Lave en genvej

Prøv denne kode som er fundet på http://delphi.about.com/library/weekly/aa091499.htm

uses ShlObj, ActiveX, ComObj;
...
procedure TForm1.Button1Click(Sender: TObject);
var
  IObject    : IUnknown;
  ISLink    : IShellLink;
  IPFile    : IPersistFile;
  PIDL      : PItemIDList;
  InFolder  : array[0..MAX_PATH] of Char;
  TargetName : String;
  LinkName  : WideString;
begin
  TargetName := 'c:\windows\calc.exe';

  {Use TargetName:=ParamStr(0) which
  returns the path and file name of the
  executing program to create a link to your
  Application}

  IObject := CreateComObject(CLSID_ShellLink);
  ISLink  := IObject as IShellLink;
  IPFile  := IObject as IPersistFile;

  with ISLink do begin
    SetPath(pChar(TargetName));
    SetWorkingDirectory
      (pChar(ExtractFilePath(TargetName)));
  end;

  // if we want to place a link on the Desktop
  SHGetSpecialFolderLocation
    (0, CSIDL_DESKTOPDIRECTORY, PIDL);
  SHGetPathFromIDList
    (PIDL, InFolder);

  {
  or if we want a link to appear in
  some other, not-so-special, folder:
  InFolder := 'c:\SomeFolder'
  }

  LinkName := InFolder + '\Delphi Created Link.lnk';
  IPFile.Save(PWChar(LinkName), false);
end;

prøver jeg lige.

Er der en måde man kan skrive parameter som "'c:\windows\calc.exe" +fullscreen +test  o.s.v?

Prøv at se lidt på eksemplet på Borrisholt.com

http://www.borrisholt.com/ShellAPI/DelphiSource/Link.zip

Prøv:

uses ComObj, ActiveX, ShlObj, Registry;
Procedure PlaceLinkOnDeskTop(FileName : TFileName; Parameter:String);

  Function GetDesktopFolder : String;
  Const
    Key = '\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\';
  begin
    Result := '';
    With TRegistry.Create do
    try
      RootKey := HKEY_CURRENT_USER;
      if OpenKey(key, FALSE) then
        Result := ReadString('Desktop');
    finally
      Free;
    end;
  end;

var
  SL: IShellLink;
  PF: IPersistFile;
  LnkName: WideString;
begin
  OleCheck(CoCreateInstance(CLSID_ShellLink, nil, CLSCTX_INPROC_SERVER, IShellLink, SL)); { IShellLink implementers are required to implement IPersistFile }
  PF := SL as IPersistFile;
  OleCheck(SL.SetPath(PChar(FileName)));  // set link path to proper file
  SL.SetWorkingDirectory(PChar(ExtractFilePath(FileName)));
  SL.SetArguments(PChar(Parameter));
  LnkName := GetDesktopFolder + #92 + ChangeFileExt(ExtractFileName(FileName), '.lnk');
  PF.Save(PWideChar(LnkName), True);      // save link file
end;