Filen vis.asp skal se sådan her ud. Den er med paging hvor den viser 10 pr side samt den søger de felter du har skrevet i spørgsmålet (Soldaternr, år, måned, navn, Kompagni):
<html>
<head>
<title></title>
</head>
<body>
<%
intPage = Request("page")
if isNumeric(intPage) = false OR intPage < 1 then
intPage = 1
end if
keyword = Request.Form("sogord")
if keyword = "" then keyword = Request.QueryString("sogord")
keyword = Replace (""&keyword,"'","''")
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="& server.mappath("brugere.mdb")
set Conn = Server.CreateObject("ADODB.Connection")
set rs = Server.CreateObject("ADODB.RecordSet")
Conn.Open strConn
'Tilføj søgning på soldaternr hvis der er indtastet et tal
if isNumeric(keyword) then
SQLWhere = "Soldaternr = " & keyword
end if
'Tilføj søgning på år hvis der er indtastet et tal
if isNumeric(keyword) then
if SQLWhere <> "" then SQLWhere = SQLWhere & " OR "
SQLWhere = SQLWhere & " [år] = " & keyword
end if
'Tilføj søgning på måned
if SQLWhere <> "" then SQLWhere = SQLWhere & " OR "
SQLWhere = SQLWhere & " [måned] LIKE '%" & keyword & "%'"
'Tilføj søgning på navn
if SQLWhere <> "" then SQLWhere = SQLWhere & " OR "
SQLWhere = SQLWhere & " [navn] LIKE '%" & keyword & "%'"
'Tilføj søgning på Kompagni
if SQLWhere <> "" then SQLWhere = SQLWhere & " OR "
SQLWhere = SQLWhere & " [Kompagni] LIKE '%" & keyword & "%'"
SQL = "SELECT * FROM gardere"
if SQLWhere <> "" then
SQL = SQL & " WHERE " & SQLWhere
end if
rs.Open SQL, conn, 1
if Not (rs.BOF Or rs.EOF) Then
rs.PageSize = 10
rs.AbsolutePage = intPage
intRecCount = rs.PageSize
intPageCount = rs.PageCount
Response.Write "<table align=""center"">"
Response.Write "<tr>"
Response.Write "<td colspan=""5"" align=""center"">"
Response.Write "<p><b>Side " & intPage & " af " & intPageCount & "</b></p>"
Response.Write "</tr>"
Response.Write "<tr>"
Response.Write "<td>Soldaternr</td>"
Response.Write "<td>År</td>"
Response.Write "<td>Måned</td>"
Response.Write "<td>Navn</td>"
Response.Write "<td>Kompagni</td>"
Response.Write "</tr>"
Do While Not rs.EOF And intRecCount > 0
Response.Write "<tr>"
Response.Write "<td>" & rs("Soldaternr") & "</td>"
Response.Write "<td>" & rs("År") & "</td>"
Response.Write "<td>" & rs("Måned") & "</td>"
Response.Write "<td>" & rs("Navn") & "</td>"
Response.Write "<td>" & rs("Kompagni") & "<td>"
Response.Write "</tr>"
intRecCount = intRecCount - 1
rs.MoveNext
Loop
keyword = replace(keyword,"''","'")
Response.Write "<tr>"
Response.Write "<td colspan=""5"" align=""center"">"
Response.Write "Gå til side "
For intNum = 1 To intPageCount
Response.Write "<a href=?page=" & intNum & "&sogord=" & keyword & ">" & intNum & "</a> "
Next
Response.Write "<p>"
if Clng(intPage) > 1 Then
Response.Write "<a href=?page=" & intPage - 1 & "&sogord=" & keyword & ">Forrige</a>"
else
Response.Write "Forrige"
end if
Response.Write " | "
if Clng(intPage) < Clng(intPageCount) Then
Response.Write "<a href=?page=" & intPage + 1 & "&sogord=" & keyword & ">Næste</a> "
else
Response.Write "Næste"
end if
Response.Write "</tr>"
Response.Write "</table>"
Else
Response.Write "<table align=""center"">"
Response.Write "<tr>"
Response.Write "<td>Fandt inden på denne søgning!</td>"
Response.Write "</tr>"
Response.Write "</table>"
End If
rs.Close
Set rs = Nothing
Conn.Close
Set Conn = Nothing
%>
</body>
</html>
