innosetup igen igen...

Pt ser det sådan her ud.
[Icons]
Name: "{commonprograms}\WinMon"; Filename: "{app}\WinchMonitor.bat"
Name: "{userdesktop}\WinMon"; Filename: "{app}\WinchMonitor.bat"
QD::

1)
  Bat filer har det ikon som brugeren angiver (oftes er
  det samme på alle PC'er da der ikke er ret mange der
  ændrer ikonet til lige netop .bat filer.

  Løsningen er at du opretter en genvej til batfilen og
  ændre ikonet i genvejen og derefter ligge genvejen på
  skrivebordet (via innosetup).
  Det betyder at der skal tilføjes en ekstra fil til din
  installer.
  Name: "{userdesktop}\WinMon"; Filename: "{app}\WinchMonitor.lnk"

2)
  Jeg har læst sætningen flere gange men jeg kan ikke helt
  finde udaf hvad det er du mener ? Kunne du omformuler /
  uddybe ?

2. Ja det er nok lidt dumt formuleret.
Når man klikker på start i windows og vælger programmer, så ser man at nogle programmer har undermenuer. Jeg ville gerne have at jeg kunne få 2 undermenuer her. En mulighed for at starte programmet, og mulighed for at se en Html.fil
QD::

Jeg tror måske at det er dette du vil:

Name: "{commonprograms}\WinMon\Help"; Filename: "{app}\help.hlp"
Name: "{commonprograms}\WinMon\Help"; Filename: "{app}\index.html"
Name: "{commonprograms}\WinMon\Foo"; Filename: "{app}\bar.txt"
Name: "{commonprograms}\WinMon\Setup"; Filename: "{app}\setup.exe"
Name: "{commonprograms}\WinMon"; Filename: "{app}\App.exe"

Lige præcis! Tak.
Mht 1. Hvad er den extension du har på batch filen Ink?
Der har forresten tiligere her været et spørgsmål ang. at det ikke skulle være muligt at få valgmuligheden om hvilken mappe men ønskede at intallerere sit program i, men svaret blev vist givet via mail desværre. Som det er nu, har man her under installation, mulighd for at vælge en anden mappe.
Hvordan kan dette undgåes, så man bliver tvunget til at installerer i den mappe man har oprettet?
QD::

Når du opretter en genvej så kommer den til at hedde f.eks.
foobar.lnk (så vidt jeg husker - jeg sidder ved en Linux maskine).


Jeg ved ikke om det kan hjælpe, men alligevel så vil jeg poste det script jeg bruger til min custom installation af Total Commander (som indeholder en del ekstra utils). Med det er det muligt for brugeren at vælge hvilket som helst destination directory - default er beskrevet i "DefaultDirName={pf}\total commander".

[Setup]
AppName=total commander
AppVerName=total commander 5.50
DefaultDirName={pf}\total commander
DefaultGroupName=total commander
DisableProgramGroupPage=yes
DisableStartupPrompt=yes
DisableReadyMemo=yes
Password=slettet...:-)
Uninstallable=no
Compression=zip/9

[Tasks]
Name: "startmenuicon"; Description: "create a &start menu icon"; GroupDescription: "Icons:"; Flags: unChecked
Name: "desktopicon"; Description: "create a &desktop icon"; GroupDescription: "Icons:"; Flags: unChecked
Name: "quicklaunchicon"; Description: "create a &quick launch icon"; GroupDescription: "Icons:"; MinVersion: 4,4

[Files]
Source: "files\*.*"; DestDir: "{app}"; CopyMode: alwaysoverwrite; Flags: recursesubdirs

[Ini]
Filename: "{app}\wincmd.ini"; Section: "Configuration"; Key: "InstallDir"; String: "{app}"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "img"; String: "0,{app}\plugins\img.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "deb"; String: "4,{app}\plugins\deb.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "iso"; String: "0,{app}\plugins\iso.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "rpm"; String: "20,{app}\plugins\rpm.wcx"
Filename: "{app}\wincmd.ini"; Section: "PackerPlugins"; Key: "cpio"; String: "20,{app}\plugins\cpio.wcx"

Filename: "{app}\wincmd.ini"; Section: "Lister"; Key: "IViewPath"; String: "{app}\tools\i_view32.exe"

Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd1"; String: "{app}\tools\bin2iso.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd2"; String: "{app}\tools\kalender.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd3"; String: "{app}\tools\md5.bat"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "param3"; String: """""{app}\tools"" ""%n"" """
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd4"; String: "{app}\tools\putty.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd5"; String: "{app}\tools\pwdspy.exe"
Filename: "{app}\wincmd.ini"; Section: "user"; Key: "cmd6"; String: "{app}\tools\upx.exe"

Filename: "{app}\wincmd.ini"; Section: "FileSystemPlugins"; Key: "$linux drives"; String: "{app}\plugins\ex2fs.wfx"
Filename: "{app}\wincmd.ini"; Section: "FileSystemPlugins"; Key: "$task manager"; String: "{app}\plugins\procfs.wfx"
Filename: "{app}\wincmd.ini"; Section: "FileSystemPlugins"; Key: "$services"; String: "{app}\plugins\services.wfx"

[Registry]
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "FtpIniName"; ValueData: "{app}\wcx_ftp.ini"
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "IniFileName"; ValueData: "{app}\wincmd.ini"
Root: HKCU; Subkey: "Software\Ghisler\Total Commander"; ValueType: string; ValueName: "InstallDir"; ValueData: "{app}"

[Icons]
Name: "{commonprograms}\total commander"; Filename: "{app}\totalcmd.exe"; Tasks: startmenuicon
Name: "{userdesktop}\total commander"; Filename: "{app}\totalcmd.exe"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\total commander"; Filename: "{app}\totalcmd.exe"; MinVersion: 4,4; Tasks: quicklaunchicon
Name: "{sendto}\hex edit"; Filename: "{app}\tools\frhed.exe"; MinVersion: 4,4

[Run]
Filename: "{app}\totalcmd.exe"; Description: "launch total commander"; Flags: nowait postinstall skipifsilent

Ja men jeg ville helst have at det ikke var en mulighed. Nå men tusind tak for svarene. Det blen næsten som jeg ønskede
QD::

Jamen, det kan da sikkert også lade sig gøre.
Prøv at kigge i hjælpen efter options i [setup] sektionen.
Det er ukendt hvornår jeg næste gang sidder ved en maskine med innosetup installeret - så jeg kan desværre ikke kigge i hjælpen for dig :-)

Et skud i tågen ville være:
DisableDirNamePage=yes

Jeg prøver. God søndag.
QD::

Det var DisableDirPage=yes
QD::