Hjælp til formel

Først denne:

=HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");((HVIS(Opret!N7="O";(Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))*1,75)-"00:30";HVIS(Opret!N7="O";(Opret!L7>Opret!M7)+Opret!M7-Opret!L7-"00:30";))

og så den anden:

=HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");(HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";);((Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))*1,75)-"00:30";HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";);(Opret!L7>Opret!M7)+Opret!M7-Opret!L7-"00:30";))

De er vist begge ved at være så kryptiske, at de er lidt svære at overskue.

Hej erikjuul
det er en kanonhjælp Du yder!
Den første formel giver lidt problemer. Ud for de lørdage og søndage hvor der er indtastet fra og til tidspunkter, men med anden bogstavbetegnelse end "FU" (Jeg har rettet formlen til bogstav "FU" i stedet for "O", skriver den -00:30

Prøv at slette -"00:30" sidst i formlen.

Som jeg tidligere har været inde på kan det være lidt svært at gennemskue alt i regnearket, når man kun ser en enkelt formel.

Jeg tror der er den samme fejl i den anden formel, her skal du også slette -"00:30" sidst i formlen.

Det løser ikke problemet, at fjerne -"00:30" sidst i formlen!

Kan du sende regnearket til mig, eller indeholder det "fabrikshemmeligheder"

Det vil gøre det noget lettere.

Jeg kan godt sende det til dig - e-mailadresse??

Send til: ejje@sisimiut.gl

Her har du 4 formler. Som du kan se har jeg ændret en del ved dem, de skulle gerne være lidt mere overskuelige nu.

AB33:
=HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";Opret!N7="FU";Opret!N7="K");((Opret!L7>Opret!M7)+Opret!M7-Opret!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30";"")

AH33:
=HVIS(ELLER(Opret!Q7="N";Opret!Q7="F";Opret!Q7="S";Opret!Q7="B";Opret!Q7="A";Opret!Q7="FU";Opret!Q7="K");((Opret!O7>Opret!P7)+Opret!P7-Opret!O7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30";"")

AC33:
=HVIS(Opret!N7="FU";((Opret!L7>Opret!M7)+Opret!M7-Opret!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"00:30";"")

AI33:
=HVIS(Opret!Q7="FU";((Opret!O7>Opret!P7)+Opret!P7-Opret!O7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"00:30";"")

Her er en kort forklaring af princippet:

Hvis denne betingelse er opfyldt: (hvis N7 er udfyldt med et af disse bogstaver)
=HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";Opret!N7="FU";Opret!N7="K");

udføres denne beregning
((Opret!L7>Opret!M7)+Opret!M7-Opret!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30";

og ellers denne: (ingenting)
"")

Beregningen der udføres:
((Opret!L7>Opret!M7)  - hvis starttid er større end sluttid lægger 1 dag til
+Opret!M7-Opret!L7)    - plus sluttid minus starttid
*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag")  - hvis lør-/søndag
;1,75    - ganges med 1,75
;1)      - og ellers med 1
-"0:30";  - og til slut trækkes den halve time fra

Hvad med bare at trække den halve time fra til allersidst ....

=HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag")=SAND;(HVIS(Opret!N7="O";(Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))*1,75;HVIS(Opret!N7="O";(Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))-"00:30"

og

=HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");(HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";);(Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))*1,75;HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";);(Opret!L7>Opret!M7)+Opret!M7-Opret!L7;))-"00:30"

Jeg kan se at mit svar fra i aftes kl. 23:30 tilsyneladende er tomt, så jeg prøver at sende formlerne igen. Jeg havde også lavet en forklaring på en af formlerne, den kommer senere.

AB33:
=HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";Opret!N7="FU";Opret!N7="K");((Opret!L7>Opret!M7)+Opret!M7-Opret!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30";"")

AH33:
=HVIS(ELLER(Opret!Q7="N";Opret!Q7="F";Opret!Q7="S";Opret!Q7="B";Opret!Q7="A";Opret!Q7="FU";Opret!Q7="K");((Opret!O7>Opret!P7)+Opret!P7-Opret!O7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30";"")

AC33:
=HVIS(Opret!N7="FU";((Opret!L7>Opret!M7)+Opret!M7-Opret!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"00:30";"")

AI33:
=HVIS(Opret!Q7="FU";((Opret!O7>Opret!P7)+Opret!P7-Opret!O7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"00:30";"")

Håber de fungerer.

janvogt>> God ide, så skal du bare lige huske at supplere med en hvis-sætning, der lægger den halve time til igen, hvis de øvrige betingelser ikke er opfyldt. :-))

Som du kan se har jeg forenklet formlerne lidt. Her er en kort forklaring af formlen i AB33 (håber den hjælper dig til at forstå, hvad der sker):

AB33:
Hvis denne betingelse er opfyldt (N7 er udfyldt med et af disse bogstaver):
=HVIS(ELLER(Opret!N7="N";Opret!N7="F";Opret!N7="S";Opret!N7="B";Opret!N7="A";Opret!N7="FU";Opret!N7="K")

så udføres denne beregning
;((Opret!L7>Opret!M7)+Opret!M7-Opret
!L7)*HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1)-"0:30"

og ellers denne (ingenting)
;"")



og selve beregningen:

;((Opret!L7>Opret!M7)    - vi starter med at lægge en (dag=24 timer) til, hvis starttid er større end sluttid
+Opret!M7      - plus sluttid
-Opret!L7)      - minus starttid
*              - så ganges der med
HVIS(ELLER(Opret!B7="Lørdag";Opret!B7="Søndag");1,75;1) hhv. 1,75 eller 1 afhængigt af om det er lør-/søndag eller ej
-"0:30"        - og til sidst trækkes den halve time fra.

erikjuul> Jeg læser bare spørgsmålet :-) Der står bare at der skal trækkes en halv time fra resultatet ......

Men jeg kan godt se, at ribo muligvis mener noget andet, men det er ikke det der står.

Mange tak for hjælpen, det virker perfekt med de sidste rettelser fra erikjuul:-)