ODBC kald fra Excel, sidst opdateret

Opdaterer du via en makro eller højreklikker du bare og bruger refresh ?

Jeg bruger refresh

Hvor er teksten blevet af.... :-(

Nååå, men du kan indsætte en makro som du skal køre efter opdatering.

Sub InsertDateTime()
  Range("A2") = "Opdateret : " & Now()
End Sub

Det er også muligt at lave en helt automatisk løsning, men det kræver lidt mere avanceret kode. interesseret ?

Ja jeg er meget ineresseret :o)

1. Opret et Classmodule og i den indsætter du følgende kode (Erstat Range("A1") med den celle du ønsker dat/tid i)
'----------

Public WithEvents qtable As QueryTable

Sub InitQueryEvent(QT As Object)
    Set qtable = QT
End Sub

Private Sub qtable_AfterRefresh(ByVal Success As Boolean)
Range("A1").Value = "opdateret : " & Now()
End Sub

'-----------

2. opret et almindeligt modul og indsæt følgende kode ( erstat "Ark1" med navnet på dit ark ):
'------

Dim clsQuerytable As New Class1
Sub RunInitQTEvent()
    clsQuerytable.InitQueryEvent QT:=Sheets("Ark1").QueryTables(1)
End Sub

'------

3. I modulet ThisWorkbook indsætter du :
'-------

Private Sub Workbook_Open()
Call RunInitQTEvent
End Sub

'-------

Når regnearket åbnes for eftertiden vil det at opdatere (refreshe) query have en AfterUpdate-event der automatisk indsætter en datio/tid i celle A1

Perfekt !