Batch: Brug af pipe commandoen "|"

Hej vitaminen
Jeg har lige scriptet denne:

@echo off
@set /a PingAntal = 2
@echo Ping statestik %date% %time%> Resultat.txt
@echo Hver IP er pinget %PingAntal% gange.>> Resultat.txt
@for /f "eol=@" %%a in (%~sf0) do ping -n %PingAntal% %%a | find "Lost = 0" > nul && echo %%a Ok >> Resultat.txt & if errorlevel 1 echo %%a Fejl >> Resultat.txt
@goto end
@Skriv IP adresser herunder
192.168.2.1
192.168.2.10
192.168.2.12
192.168.2.2
192.168.2.3
@:end
@start notepad.exe Resultat.txt

Håber du kan bruge den :-)

FANDME nice scriptet.

Jeg er lige startet på det fis her, for nogle dage siden. Egentlig meget underholdende :)

Hvordan har du lært dig det? Bare læst lidt hist og her?

Du fortjener points :)
\ Rune

Måske du kunne forklare mig denne linie bare lige kort? :)

@for /f "eol=@" %%a in (%~sf0) do ping -n %PingAntal% %%a | find "Lost = 0" > nul && echo %%a Ok >> Resultat.txt & if errorlevel 1 echo %%a Fejl >> Resultat.txt

Ville være kanon

Forstår ikke:

@for /f "eol=@" %%a in (%~sf0)

find "Lost = 0" > nul && <- betyder det bare at den ikke skal skrive resultatet nogen steder?

Et godt sted at søge information er Windows Help.

"for"  komandoen gennemløber filen (%~sf0) denne fil linie for linie. Og læser linien ind i variablen %a (Ja det er %a og ikke %%a, det er kun i batch filer at den angives med 2 %%, i en komando prompt er det %a)

"eol=@"  siger at End Of Line tegnet er @, det vil sige at linier der starter med @ "springes over"

"ping -n %PingAntal% %%a"  Her pinger vi bare.

" | find "Lost = 0" > nul"  Sender ping resultatet til find, der undersøger om resultatet indeholder "Lost = 0", outputtet fra ping sendes til nul (det forsvinder ind i de evige bit marker).

"&&"  betyder: Hvis den forige komando lykkedes (find fandt "Lost = 0") så udfør den næste komande, ellers ikke.

"echo %%a Ok >> Resultat.txt"  skriv IP og Ok i filen, Resultat.txt

"&"  skilleteg mellem 2 komandoer på samme linie.

"if errorlevel 1 echo %%a Fejl >> Resultat.txt"  find fandt ikke "Lost = 0", så vi skriver IP og Fejl i Resultat.txt


Jeg håber at dette kan hjælpe, det er faktisk sværere at beskrive et script, for en uøvet, end det er at skrive det.

:-)

:-)

Har du glemt at ta' din pille (vitaminpille)?

Hehe :)

Jeg har haft galt travlt de sidste mange dage.´

Fantastisk forklaring. Du fortjener point.

\ Rune

Hamrende godt script, kører det dagligt for at checke om alle servere og printere er oppe.
Er der mulighed for at få dette script til også at vise hostaddresse?