installation af runtime tilføj AxtiveX

Hvilken version bruger du?

juks>If you use the setup wizard then you can add ActiveX controls using this. Then they get installed when you run the setup!

Jeg har et par stumper kode du måske kan bruge.

Sub tilfoejRef()
    'tilføj reference til Microsoft Visual Basic for Applications Extensibility 5.3
    Application.VBE.ActiveVBProject.References.AddFromGuid "{0002E157-0000-0000-C000-000000000046}", 5, 0

End Sub

Når du har tilføjet ovenstående ref. kan denne procedure fjerne alle missing referencer:

Sub fjernMissingRefs()

    Dim ref As VBIDE.Reference
    With Application.VBE.ActiveVBProject
        For Each ref In .References
            If ref.IsBroken Then
                .References.Remove ref
            End If
        Next
    End With
       
End Sub

Dette er kopieret fra en tysk side og registrer Comctl32.ocx vha API functionen
DllRegisterServer.


Declare Function RegComCtl32 Lib "Comctl32.ocx" Alias "DllRegisterServer" () As Long
Declare Function UnRegComCtl32 Lib "Comctl32.ocx" Alias "DllUnregisterServer" () As Long

Const S_OK = &H0


Sub RegisterComCtl32()

On Error GoTo Err_RegisterComCtl32

If RegComCtl32 = S_OK Then
  MsgBox "Registrierung erfolgreich."
Else
  MsgBox "Registrierung nicht möglich."
End If

Exit_RegisterComCtl32:
Exit Sub

Err_RegisterComCtl32:
MsgBox "RegisterComCtl32" & vbCrLf & Err.Number & vbCrLf & Err.Description
Resume Exit_RegisterComCtl32

End Sub


Sub UnregisterComCtl32()

On Error GoTo Err_UnregisterComCtl32

If UnRegComCtl32 = S_OK Then
  MsgBox "Registrierung aufgehoben."
Else
  MsgBox "Aufhebung der Registrierung nicht möglich."
End If

Exit_UnregisterComCtl32:
Exit Sub

Err_UnregisterComCtl32:
MsgBox "UnregisterComCtl32" & vbCrLf & Err.Number & vbCrLf & Err.Description
Resume Exit_UnregisterComCtl32

End Sub

jeg registrede bare det forkerte komponent :-)