Blanke celler ....

Hej Smoothj

Nedenstående kode, løber tabellen igennem, og fylder tomme celler ud med værdien af cellen ovenover.

Hvis tabellen starter med en tom celle, vil de efterfølgende celler blive udfyldt med denne værdi; altså ingenting.

--- Kode start ---

Public Sub FillEmptyCells()

    Dim rst As ADODB.Recordset
    Dim strBuffer As Variant
   
    Set rst = New ADODB.Recordset
   
    rst.Open \"tblMain\", CurrentProject.Connection, adOpenForwardOnly, adLockOptimistic
   
    strBuffer = rst(0)
    rst.MoveNext
    Do While Not rst.EOF
        If VarType(rst(0)) = vbNull Then
            rst(0) = strBuffer
            rst.Update
        Else
            strBuffer = rst(0)
        End If
        rst.MoveNext
    Loop
   
End Sub

--- Kode slut ---

Jeg går i koden ud fra, at cellen der skal udfyldes i er den første i tabellen (rst(0)). hvis ikke, skal du ændre de nul-baserede indeks til den rigtige værdi.

Desuden skal du selvfølgelig ændre navnet på tabellen til det navn du har (tblMain -> <ditTabelNavn).

Jeg går ud fra, at du benytter Access 2K og har sat en reference til ADO (er gjort som standard), hvis ikke kan du lige skrive, så an jeg lave det om til DAO (Access 97).

Med venlig hilsen

LKP

Kære lkp

Jeg har 97 så hvis du kan ændre det vil jeg blive glad  så prøver jeg det i morgen

1000 tak

:o]

Hej Smoothj

Hermed kode der virker i 97

--- Kode start ---

Public Sub FillEmptyCells()

    Dim rst As Recordset
    Dim strBuffer As Variant
   
    Set rst = CurrentDb.OpenRecordset(\"tblMain\", dbOpenDynaset)
       
    strBuffer = rst(0)
    rst.MoveNext
    Do While Not rst.EOF
        If VarType(rst(0)) = vbNull Then
            rst.Edit
            rst(0) = strBuffer
            rst.Update
        Else
            strBuffer = rst(0)
        End If
        rst.MoveNext
    Loop
   
End Sub

--- Kode slut ---

Håber du kan bruge det.

Med venlig hilsen

LKP

Hhhhmmmm ......

Hvor fortæller man hvilken kolonne den skal kigge i ?

Jeg beklager men jeg ved kun ganske ganske lidt om Access og især VBA i Access.

.o]
:o]

Hej Smoothj

Den kolonne der skal kigges i bestemmes af \"rst(0)\". Hvis det er den første kolonne i din tabel er det rst(0), den anden rst(1), den tredie rst(2) osv.

Du kan dog også vælge at skrive kolonne navnet istedet. Hvis det feks er kolonnen med navnet \"bogstav\" du ønsker, at fylde ud, skal du skrive rst(\"bogstav\") alle de steder hvor der nu står rst(0).

Håber, at du kan bruge ovenstående, ellers skriv igen.

Med venlig hilsen

LKP

Hej LKP, super svar - har tit manglet den stump kode når jeg arbejder med at "rense" data! Tak for det!