Datediff - countdown problem

Jeg har faktisk en lavet et par funktioner, som kan den du forespørger!.. Det eneste du skal fodre den med, er en dato:

Function SecondsToText(Seconds)
Dim bAddComma
Dim Result
Dim sTemp

If Seconds <= 0 Or Not IsNumeric(Seconds) Then
    SecondsToText = "0 " & strSeconds
    Exit Function
End If

Seconds = Fix(Seconds)

If Seconds >= 86400 Then
  days = Fix(Seconds / 86400)
Else
  days = 0
End If

If Seconds - (days * 86400) >= 3600 Then
  hours = Fix((Seconds - (days * 86400)) / 3600)
Else
  hours = 0
End If

If Seconds - (hours * 3600) - (days * 86400) >= 60 Then
minutes = Fix((Seconds - (hours * 3600) - (days * 86400)) / 60)
Else
minutes = 0
End If

Seconds = Seconds - (minutes * 60) - (hours * 3600) - _
  (days * 86400)

If Seconds > 0 Then Result = Seconds & "&nbsp;" & AutoS(Seconds, "isSecond")

If minutes > 0 Then
    bAddComma = Result <> ""
   
    sTemp = minutes & "&nbsp;" & AutoS(minutes, "isMinute")
    If bAddComma Then sTemp = sTemp & ", "
    Result = sTemp & Result
End If

If hours > 0 Then
    bAddComma = Result <> ""
   
    sTemp = hours & "&nbsp;" & AutoS(hours, "isHour")
    If bAddComma Then sTemp = sTemp & ", "
    Result = sTemp & Result
End If

If days > 0 Then
    bAddComma = Result <> ""
    sTemp = days & "&nbsp;" & AutoS(days, "isDay")
    If bAddComma Then sTemp = sTemp & ", "
    Result = sTemp & Result
End If

SecondsToText = Result
End Function


Function AutoS(Number, what)
    select case what
        case "isDay"
            dt1 = strDay
            dt2 = strDays
        case "isSecond"
            dt1 = strSecond
            dt2 = strSeconds
        case "isMinute"
            dt1 = strMinute
            dt2 = strMinutes
        case "isHour"
            dt1 = strHour
            dt2 = strHours
        case "isDay"
            dt1 = strDay
            dt2 = strDays
        End select
       
    If Number = 1 Then AutoS = dt1 Else AutoS = dt2
End Function

Du skal dog lige ændre i mine language-variabler, således, at den outputter på det sprog du gerne vil ha'!

Du bruger den således:

Response.Write SecondsToText(dateDiff("s",now(),mrs("ReleaseDate")))

Mvh,

/thomas regin.

Hej Thomas,

Jeg prøver lige at lege med det og se om jeg kan tilpasse det, så vender jeg lige tilbage ok :)

Alright!..

Det eneste du faktisk skal ændre:

Function AutoS(Number, what)
    select case what
        case "isDay"
            dt1 = "Dag"
            dt2 = "Dage"
        case "isSecond"
            dt1 = "Sekund"
            dt2 = "Sekunder"
        case "isMinute"
            dt1 = "Minut"
            dt2 = "Minutter"
        case "isHour"
            dt1 = "Time"
            dt2 = "Timer"
        case "isDay"
            dt1 = "Dag"
            dt2 = "Dage"
        End select
       
    If Number = 1 Then AutoS = dt1 Else AutoS = dt2
End Function

Mvh,

/thomas regin.

Thomas.... det lader jo til at virke perfekt!!! ...men det vidst du vel ;)

TUSIND tak for hjælpen!

hilsener

Tommy

Hehe.. Jeg havde ihvertfald en idé om det! ;)

Mange tak for pointene og god fornøjelse med det!

Mvh,

/thomas regin.