Global asa fil ?

Du kan desværre ikke bruge denne metode, idet Server-objektet allerede er nedlagt af webserveren, når Session_OnEnd og Application_OnEnd kaldes.
Måden at løse det på kan være at oprette dine objekter allerede i Session_OnStart og gemme dem i Session- eller Application-variable.

Men bare for en ordens skyld: Hvis serveren går ned (uplanlagt), kaldes der vist slet ikke nogen funktioner fra global.asa, idet der jo så ikke er nogen server til at udføre dem ;-)

/torben

Du kunne eksempelvis udføre din oprydning efter nedbrud (Applcation_OnEnd) i Application_OnStart i stedet for. For når den udføres må der ikke være nogen uafsluttede handler i databasen.

/torben

Ok så langt så godt jeg vil kigge lidt på det og om ikke andet kan det jo laves i ren asp kode :o)

/vb-mo

Prøv at kikke her
http://www.planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=6632&lngWId=4

dta >> Ok og den afviger ikke meget fra min og vi er enige om at global.asa skal ligge i www roden ikke sandt ?

Jo, Global.asa skal ligge i roden.

Forskellen mellem det du har lavet og dette er som <tjol> skriver at server objektet er nedlagt, men det er  sessionen ikke.

problemet med det eksempel er at den er ufuldstændig, idet den jo ikke viser hvordan sql'en skal udføres. Du er jo nødt til at have en åben database-connection - eller lave en.
Jeg sagde noget vrøvl før: det er ikke hele Server-objektet, der er nedlagt, men Server.MapPath findes ikke i Session_OnEnd (spørg mig ikke hvorfor:-/)
Men den findes i Session_OnStart, så du kan gemme din databasesti der i en session-variabel:

Sub Session_OnStart
Session("dbsti") = Server.MapPath("data/shop.mdb")
End Sub

Sub Session_OnEnd
    ' ==========================================================================
    ' Sletter besøgendes kurv når han/hun forlader siden,
    ' dette gælder for ikke gennemførte handler.
    ' ==========================================================================

    On Error Resume Next
    Set Conn = Server.CreateObject("ADODB.Connection")
    Conn.Open = "driver={Microsoft Access Driver (*.mdb)};dbq=" & Session("dbsti")
    SQLStmt = "DELETE FROM Cart Where SubId =" & Session.SessionId & " AND SendOrder <> 1"
    Conn.Execute(SQLStmt)
    Conn.Close
End Sub

Sub Application_OnStart
Application("dbsti") = Server.MapPath("data/shop.mdb")

    On Error Resume Next
    Set Conn = Server.CreateObject("ADODB.Connection")
    Conn.Open = "driver={Microsoft Access Driver (*.mdb)};dbq=" & Application("dbsti")
    SQLStmt = "DELETE FROM Cart Where SendOrder <> 1"
    Conn.Execute(SQLStmt)
    Conn.Close

End Sub

Sub Application_OnEnd
    ' ==========================================================================
    ' Hvis serveren går ned eller genstartes sletter vi alle ikke færdig gjorte
    ' handler igennem shoppen.
    ' ==========================================================================
   
    On Error Resume Next
    Set Conn = Server.CreateObject("ADODB.Connection")
    Conn.Open = "driver={Microsoft Access Driver (*.mdb)};dbq=" & Application("dbsti")
    SQLStmt = "DELETE FROM Cart Where SendOrder <> 1"
    Conn.Execute(SQLStmt)
    Conn.Close
End Sub

Med denne får du også ryddet uafsluttede handler af, hvis de ikke er ryddet op pga et nedbrud el.lign.

/torben

Ok jeg tester lige :o)

Det virker tak for hjælpen begge to :o)

you are welcome :-)

/torben