AspSmartUpload saveas

Eks på savaas.

mysmartUpload.files.item(1).saveas "/aspSmartUpload/fil.jpg"


Og den skriver: 'Invalid Files Name'
Så et tyder på det er ugyldigt filnavn eller en sti den ikke kan finde.

Kan den saa ikke finde stien paa den fil jeg uploader (???) eller kender den ikke destinationen?

Det er lykkedes mig at uploade een fil, men nu faar jeg fejlen altid...

Hvad er det man skriver, naar man skriver 1 som parameter?

En smule lost her!!!

Den kender altid stien på den fil den uplaoder.
Men du skal angive stien +evt filnav hvor du vil havde gemt filen.

Hvis du vil gemme filen med samme navn som den har så bruge save:

mysmartUpload.save "/upload/files"


Hvis du vil bestemme filnanvet den så bruge saveas

mysmartUpload.files.item(1).saveas "/upload/files/NYTNAVNPÅFILEN.jpg"

Ja det skulle jeg mene jeg havde styr paa.
Jeg synes bare at jeg goer alt det rigtige men den brokker sig alligevel...hmmm

Min saveas ser ud som den du viser her (lige bortset fra stien) og jeg faar alligevel fejlen. Kan det vaere noget andet i min kode saveas afhaenger af, der er "forkert"?

Har du kaldt .upload for at uplaode filerne??
Det skal gøres inden man kan lave saveass


mySmartUpload.Upload

Min kode ser saadan her ud:
Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")
mySmartUpload.AllowedFilesList = "jpg, jpeg"
mySmartUpload.DenyPhysicalPath = True
mySmartUpload.Upload
mysmartUpload.files.item(1).saveas "../grafik/fil.jpg"

Er grafik i root på serveren så prøv at fjerne .. måske det endre noget:

mysmartUpload.files.item(1).saveas "/grafik/fil.jpg"

Det aendrer dsv. ikke noget.
Jeg gaar ud fra at den skal gemmes til en virtuel sti!?

http://www.aspsmart.com/aspSmartUpload/

her bruger de 3 linier... er det noedvendigt?

Du kan prøve at sætte server.mappath på


mysmartUpload.files.item(1).saveas Server.MapPath("../grafik/fil.jpg")

Ingen bedring med det heller.

Jeg brugte denne kode oprindeligt:
http://www.aspsmart.com/scripts/aspSmartUpload/publigen/content/templates/show.asp?P=354&L=EN

og har saa senere aendret "save"-delen med "saveas"

Prøv at lave din kode om til dette hvor DenyPhysicalPath  er udkommenteret og filen gemmes med server.mappath


Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")
mySmartUpload.AllowedFilesList = "jpg, jpeg"
'mySmartUpload.DenyPhysicalPath = True
mySmartUpload.Upload
mysmartUpload.files.item(1).saveas Server.MapPath("../grafik/fil.jpg")

Det aendrer dsv. heller ikke noget, den brokker sig stadig over det 1-tal i item(1)

Er det 1 tallet som driller?

Du kan prøve at tjekke på om filen er med:

if mysmartUpload.files.item(1).isMissing = false then
  mysmartUpload.files.item(1).saveas Server.MapPath("../grafik/fil.jpg")
end if



Husk din form tag skal indeholder dette:
ENCTYPE="multipart/form-data"

Jeg har husket enctype i min form.

Jeg har udskiftet min oprindelige saveas linie med den nye if-sætning, men den giver samme problem...
Nu håber jeg ikke det er en eller anden dum fejl fra min side.

Hvis du kun har behov for at upload3e et enkelt billede ad gangen, så burde denne kunne bruges.. den virker upåklageligt hos mig...

Det er grund-script fra aspSmart.com, som er modificeret til mine behov...

------------------------------------------
<%
'  Variabler
'  *********
  Dim mySmartUpload
  Dim file
  Dim intCount
  Dim Size
  Dim Filename
  Dim FileExt
  Dim FilePathName
  Dim NewName
  Dim Fil
  intCount=0
       
'  Opret Object
'  ***************
  Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")

'  Upload
'  ******
  mySmartUpload.Upload

'  Vælg hver fil
'  ****************
  For each file In mySmartUpload.Files
  '  Kun hvis filen findes
  '  **********************
 
        If not file.IsMissing Then
 
  '  Lav variabler ud fra billedets info
      '  ******************************************
        Size =  file.Size & " Bytes"
        FileName = file.FileName
        FileExt = "." & file.FileExt
        FilePathName =  file.FilePathName
        FileVirtPath =  mySmartUpload.Form("Sti") 

 
      '  Gem fil på serveren afhængigt af value i <select>
      '  Lav et unikt filnavn ned brug af nogle tal i date/time
      '  **************************************************************************
     
      NewName = right("0" & year(now), 2) & right("0" & month(now), 2) & right("0" & day(now), 2)
      NewName = NewName & hour(time) & minute(time) & second(time)
     
      Fil = NewName & FileExt
     
     
     
          file.SaveAs("/Pics/" & FileVirtPath & Fil)
        ' eksempel med en fysisk sti
        ' file.SaveAs("c:\temp\" & file.FileName)

     

        intCount = intCount + 1
      End If
  Next

%>
----------------------------------------

/Mads

Fedt, det ser ud til at virke!!!

Det nye filnavn afhænger så af nogle radiobuttons i formen. Der ville jeg bruge request.form("billede"), men så får jeg fejlen:
Cannot call BinaryRead after using Request.Form collection.

Du må ikke bruge Request.Form i en mySmartUpload form ...  så kald den med..

mySmartUpload.Form("Billede")

(alt afhængig af om du kalder hele upload objectet med "mySmartUpload" )

Jeg havde selv samme fejl i starten nemlig ;o)

/Mads

Tak for hjælpen og din/jeres tid

Christ

Det var så lidt :o)

/Mads