Omdøb access tabel og kolonnenavn

Det kan du godt, prøv at se her engang:
www.w3schools.com/sql/

//>Rune

Da man ikke direkter med SQL kan ændre navet ko en tabel må man bruge ADOX.Catalog som er det enste jeg har fundet som kan lave tabel nanvet om. Det skal være OLE DB provideren man bruger til at connecte til databasen eller virker dette ikke altid.

Prøv med dette styk kode. Det virker til en Access database:



<%
connStr = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("db101.mdb")

nytNavn = "detnyenavn"
gammeltNavn = "test"

'Det skal være OLE DB provideren eller virker dette ikke altid
Dim objADOXDatabase
Set objADOXDatabase = Server.CreateObject("ADOX.Catalog")
objADOXDatabase.ActiveConnection = connStr

'Change the name...
objADOXDatabase.Tables(gammeltNavn).Name = nytNavn

'Clean up...
Set objADOXDatabase = Nothing
%>



På samme måde kan det laves som ændre navnet på kolonnen:


<%
connStr = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("db101.mdb")

nytNavn = "detnyenavn"
gammeltNavn = "test"

'Det skal være OLE DB provideren eller virker dette ikke altid
Dim objADOXDatabase
Set objADOXDatabase = Server.CreateObject("ADOX.Catalog")
objADOXDatabase.ActiveConnection = connStr

Set tbl = objADOXDatabase.tables("Navn_På_Tabellen_Hvor_Kolonnen_Er")

nytKolNavn = "detnyenavn"
gammeltKolNavn = "test"

tbl.Columns(gammeltKolNavn).Name = nytKolNavn

'Clean up...
Set objADOXDatabase = Nothing
%>

>> eageleye

Der ser godt ud dit forslag, jeg har ikke lige tid til at prøve det her i weekenden, men jeg vender tilbage, når jeg har prøvet det.

Jeg er super glad for forslaget, for jeg har abselut ikke kunne finde en skid om det nogen steder....!!!! :-))))

Det virker helt perfekt, tak for hjælpen.