Så ikke lige din kommentar - men skidt, det tog heller ikke så lang tid. Her er et komplet eksempel. Det eneste, du skal ændre, er de to konstanter STR_DB og STR_TB, som er hhv. navnet på databasen og navnet på tabellen.
Håber, det er noget i denne dur, du efterspørger:
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<%
Const STR_DB = "db.mdb"
Const STR_TB = "tbElements"
Sub writeElements(pid,level)
Dim rs, rs2, intCount, strSql, boolHasChildren
strSql = "SELECT * FROM " & STR_TB & " WHERE parentid=" & pid
Set rs = Conn.Execute(strSql)
If Not rs.Eof Then
Do While Not rs.Eof
boolHasChildren = False
strSql = "SELECT Count(*) AS intCount FROM " & STR_TB & " WHERE parentId=" & rs("id")
Set rs2 = Conn.Execute(strSql)
If rs2("intCount") > 0 Then boolHasChildren = True
rs2.Close
Set rs2 = Nothing
If boolHasChildren Then
Response.Write "<a href=""#"" onclick=""toggleNode(" & rs("id") & ")"">" & rs("name") & "</a><br>"
Response.Write "<div id=""cont" & rs("id") & """ style=""margin-left:" & 15 * (level+1) & "px; display:none"">"
WriteElements rs("id"), level + 1 'udskriv alle elementer under dette
Response.Write "</div>"
Else
Response.Write rs("name") & "<br>"
End If
rs.MoveNext
Loop
End If
rs.Close
Set rs = Nothing
End Sub
%>
<HTML>
<HEAD>
<TITLE>Tælletræ</TITLE>
<SCRIPT LANGUAGE="JavaScript">
function toggleNode(intNd) {
var srcElm = event.srcElement;
var coll = document.getElementsByTagName('a');
for (var i=0; i<coll.length;i++) {
if (coll[i] == srcElm) srcElm.style.fontWeight = 'bold';
else coll[i].style.fontWeight = 'normal';
}
var elm = document.getElementById('cont' + intNd);
elm.style.display = (elm.style.display == 'none') ? 'block' : 'none';
}
</SCRIPT>
</HEAD>
<BODY>
<%
Dim Conn
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(".") & "\" & STR_DB
writeElements 0,0
Conn.Close
Set Conn = Nothing
%>
</HTML>
Ny bruger
Nybegynder
Opret
Preview
