Langsom domænetester

Hej alle sammen,

Jeg er pt. ved at lave en domænetester og er kommet frem til følgende:

<%
function doWhois(Domain, Scope)
  Domain = LCase(Domain)

  Host = ""
  if InStr(Domain, ".dk") <> 0 then
    Host = "www.dk-hostmaster.dk"
    SearchStr = "# No entries found for the selected source."
  elseif InStr(Domain, ".com") <> 0 or InStr(Domain, ".net") <> 0 then
    Host = "rs.internic.net"
    SearchStr = "No match for "
  elseif InStr(Domain, ".org") <> 0 then
    Host = "whois.opensrs.net"
    SearchStr = "NOT FOUND"
  elseif InStr(Domain, ".nu") <> 0 then
    Host = "whois.nic.nu"
    SearchStr = "NO MATCH for domain "
  elseif InStr(Domain, ".biz") <> 0 then
    Host = "whois.nic.biz"
    SearchStr = "Not found"
  elseif InStr(Domain, ".info") <> 0 then
    Host = "whois.opensrs.net"
    SearchStr = "NOT FOUND"
  elseif InStr(Domain, ".ws") <> 0 then
    Host = "whois.nic.ws"
    SearchStr = "No match for"
  elseif InStr(Domain, ".as") <> 0 then
    Host = "whois.nic.as"
    SearchStr = "Domain Not Found"
  elseif InStr(Domain, ".se") <> 0 then
    Host = "whois.nic-se.se"
    SearchStr = "No data found."
  end if

  if Host <> "" then
    set Socket = Server.CreateObject("Socket.TCP")
    Socket.Host = Host & ":43"
    Socket.Open
    Socket.SendLine(Domain)
    Socket.WaitForDisconnect
    Result = Socket.Buffer
    Socket.Close
    if Scope="short" then
      doWhois = InStr(Result, SearchStr)  ' 0: domain already exist, >0: domain is free for register
    else
      doWhois = Result
    end if
    set Socket = nothing
  else
    doWhois = -1  ' Unknown TLD
  end if
end function %>

<table border="1" width="50%">

<tr>
<th>TLD</th>
<th>Før</th>
<th>Efter</th>
<th>Difference</th>
</tr>

<%
All_TLD = "dk,com,net,org,biz,info,as,nu,ws,se"
TLD = split(All_TLD, ",")

for i=LBound(TLD) to UBound(TLD)
  FullDomain = "NogetEtEllerAndet." & TLD(i)
  Time1 = Time()
  Calc_doWhois = doWhois(FullDomain, "short")
  Time2 = Time()
  TimeDiff = DateDiff("s", Time1, Time2) %>
<tr>
<td align="center"><% =TLD(i) %></td>
<td align="center"><% =Time1 %></td>
<td align="center"><% =Time2 %></td>
<td align="center"><% =TimeDiff %></td>
</tr>
<%
next %>