Automatisk nyhedsbrev.

hvis det selv skal sende brevet uden bruger beder om det:
http://activedeveloper.dk/aspdigital/2002080801.asp

Laver et opslag i databasen og tager nyheden med den nyeste dato. I MS SQL kan du oprette et task, der automatisk kører et script f.eks. hver mandag morgen.

Ja, global.asa er også en mulighed, men det kræver så, at der kommer nye sessions for at koden vil blive afviklet.

Men hvad gør jeg hvis jeg vil have dem med i nyhedsbrevet (altså nyhederne)?

Altså det jeg mener er:

Hvordan skal jeg sende en mail ud med asp indhold... Hvordan kunne man for eksempel trække noget ud fra en database og så skrive det i emailen...

Jeg er ikke sikker på, hvad du helt præcis vil have hjælp til.

Er det til at trække posten ud af tabellen, er det til at afsende mails'ne, eller er det til at afvikle filen med bestemt interval?

Jamen jeg er ikke helt sikker på hvordan jeg for eksempel trækker en nyhed ud fra en database og skrive den i mailen... Det andet har jeg fundet ud af...

/Jens

Lad os sige, du har en tabel med følgende kolonner:

ID          Dato          Nyhed
1        2003-08-23      Bla bla
2        2003-08-24      Bla bla

Så kan du trække den sidste nyhed ud således:

Set rs = Conn.Execute("Select Top 1 Dato, Nyhed From Tabel Order By Dato Desc")

Dato = rs("Dato")
Nyhed = rs("Nyhed")

Og så vil du typisk have en tabel med modtageres navne og mail-adresser:

ID          Bruger        Email
1          Peter      peter@hotmail.com
2          Benny      benny@hotmail.com

Herefter kan du løbe tabellen med brugerne i gennem og sende dem en mail hver med f.eks. ASPmail:

Set rs = Conn.Execute("Select Bruger, Email From Tabel")
While Not rs.EOF

  Set AspMail = Server.CreateObject("SMTPsvg.Mailer")
  AspMail.FromName = "Dit navn"
  AspMail.FromAddress = "din@mailadresse.dk"
  AspMail.AddRecipient rs("Bruger"), rs("Email")
  AspMail.Subject = "Nyhed d. " & Dato
  AspMail.BodyText = "Hej " & rs("Bruger") & "!" & vbCrlf & vbCrlf & Nyhed

  'Mailserver
  AspMail.RemoteHost = "mail.domaene.dk"

  If AspMail.SendMail Then
      Response.Write "Mail sendt til " & rs("Bruger") & "<br>"
  Else
      Response.Write "Der opstod følgende fejl: " & AspMail.Response & "<br>"
  End If

  Set AspMail = Nothing

  rs.MoveNext
Wend

http://www.opfinderen.dk/sites/?id=14

netro --> gider du ikke lige forklarer hvordan du får nyhederne ind i emailen... Tor jeg er ved at fatte lidt af det ;-)....


/Jens

Nu fatter jeg til gengæld ikke, hvad du siger ;)

Ind i e-mail'en? Vi henter jo alle oplysninger fra de to tabeller, som du selvfølgelig også skal have skabt. Men som jeg læser dit spørgsmål, var det ikke det, der er problemet.

Jamen inde i " AspMail.BodyText = "Hej " & rs("Bruger") & "!" & vbCrlf & vbCrlf & Nyhed " - hva gør man der for at nyhed køre i loop?

/Jens

Der skal du ikke køre noget loop. Loop'et består af hele mail-scriptet (fra While til Wend).

Eller vil du udsende flere nyheder fra tabellen i samme mail til hver bruger...?

Ja lige præcist! Jeg skal sende omkring 10-15 nyheder ud med samme mail...

/Jens

Nååh, okay :)

Med udgangspunkt i før viste tabeller, trækker vi først de 15 seneste nyheder ud og gemmer dem i variablen "Body". Derefter løber vi hver bruger i gennem og sender vedkommende nyhederne:

*******************************************************

Set rs = Conn.Execute("Select Top 15 Dato, Nyhed From Tabel Order By Dato Desc")
While Not rs.EOF
  Body = Body & vbCrlf & vbCrlf & rs("Dato") & vbCrlf & rs("Nyhed")
  rs.MoveNext
Wend

Set rs = Conn.Execute("Select Bruger, Email From Tabel")
While Not rs.EOF

  Set AspMail = Server.CreateObject("SMTPsvg.Mailer")
  AspMail.FromName = "Dit navn"
  AspMail.FromAddress = "din@mailadresse.dk"
  AspMail.AddRecipient rs("Bruger"), rs("Email")
  AspMail.Subject = "Nyhed d. " & Dato
  AspMail.BodyText = "Hej " & rs("Bruger") & "!" & Body

  'Mailserver
  AspMail.RemoteHost = "mail.domaene.dk"

  If AspMail.SendMail Then
      Response.Write "Mail sendt til " & rs("Bruger") & "<br>"
  Else
      Response.Write "Der opstod følgende fejl: " & AspMail.Response & "<br>"
  End If

  Set AspMail = Nothing

  rs.MoveNext
Wend

Overskriften på mails'ne skal du også lige ændre til f.eks.:

AspMail.Subject = "De 15 seneste nyheder"

Tjekker lige om jeg kan få det til og virke også få du point ok?!

/Jens

Bare lige et hurtigt spørgsmål... Hvordan er det at man får den til kun at trække de første 200 tegn ud i nyhedsblokken?

Tusind tak for hjælpen...

Piont er:

Netro = 150
mm12010 = 50

Left(Nyhed, 200)

Eller Left(Nyhed, netro + mm12010)

;o)