2 spalter med med underlæggende sider!

Prøv noget som dette, hvor conn er nanvet på din Connection til databasen:

<%
SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"
Set rs = Conn.Execute(SQL)

lastID = ""
response.write "<table>"
colPrRow = 0
maxPrRow = 2
do while not rs.EOF
  if colPrRow = 0 then Response.write "<tr>"

  if lastID <> rs("TKID") then
    Response.Write "<td>"
    response.write "<table>"
    response.write "<tr><td>TKID:" & rs("TKID") & "</td></tr>"
    lastID = rs("TKID")
    colPrRow = colPrRow + 1
  end if

  response.write "<tr><td>-Tkategori=" & rs("Tkatagori") & "</td></tr>"
 
  rs.Movenext

  if not rs.EOF then
    if lastID <> rs("TKID") then
      Response.Write "</table>"
      Response.Write "</td>"
    end if
  else
    Response.Write "</table>"
    Response.Write "</td>"
  end if

  if colPrRow = maxPrRow then
    colPrRow = 0
    response.write "</tr>"
  end if
loop
if colPrRow > 0 then response.write "</tr>"
response.write "</table>"
%>

Jeg henter på nuværende tidspunkt databasen således:

<!--#include file="../Connections/gratis.asp" -->

database filen!!............
<%
MM_gratis_STRING = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=d:\home\smzdk\www\demo\database\database.mdb"
%>

hvorledes skal jeg ændre conn????

Ok, så prøv at rette disse linjer i den kode jeg har vist:

SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"
Set rs = Conn.Execute(SQL)


Til dette:

Set rs = Server.CreateObject("ADODB.Recordset")
SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"
rs.Open SQL, MM_gratis_STRING, 1

Nu sker der noget den kommer dog med følgende fejl!

ADODB.Recordset error '800a0bb9'

Arguments are of the wrong type, are out of acceptable range, or are in conflict with one another.

/demo/sider/test.asp, line 11  -> er rs.Open SQL, MM_gratis_STRING, 1

Har du includet din connection fil?

<!--#include file="../Connections/gratis.asp" -->

det har jeg nu! og den kommer med følgende fejl:
---------------------------------------------------
Microsoft JET Database Engine error '80040e10'

No value given for one or more required parameters.

/demo/sider/test.asp, line 12 -> stadig  rs.Open SQL, MM_gratis_STRING, 1

Prøv at lave disse linjer:

Set rs = Server.CreateObject("ADODB.Recordset")
SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"
rs.Open SQL, MM_gratis_STRING, 1


Om til:

Set rs = Server.CreateObject("ADODB.Recordset")
Set conn = Server.CreateObject("ADODB.Connection")
conn.Open  MM_gratis_STRING
SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"
Set rs = Conn.Execute(SQL)

databasen er ikke tom! der er 3 kategorier med 2-4 underkategorier hver, og en kategori uden underkategorier!

den kommer med samme fejl med den sidst kode!

Er alle tabel og kolonnenavne rigtige i den SQL sætning??

SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.TKID ORDER BY kategorier.TKID ASC"

Er det TKID i begge tabeller som gør de skal JOIN's?

Ja jeg har kopieret dem direkte fra access databasen!!

tabel: kategorier

TKID, TKoverskrift

Tabel: tekster

TID, Toverskrift, Tkatagori

TKID kan have flere underkategorier og er relateret til Tkatagori

Arh så tebellen i tekster er Tkatagori der høre til TKID i tabellen kategorier:

Prøv lige denne SQL:

SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.Tkatagori ORDER BY kategorier.TKID ASC"

nu virker det helt perfekt!

Lige en sidste ting, hvis jeg gerne vil have dataerne:

TKoverskrift (dens data f.eks. forside)    istedet for "TKDI:"
- Toverskrift (dens data f.eks. service)  istedet for "- Tkategori="

samt at alle cellerne starter øverest, istedet for at de centreres!

og den aller sidste ting at tabellen er 100% bred

Du kan tilføje de kolonner der er behov for i SQL sætningen evt bare skrive * hvis der ikke er to kolonne som hedder det samme i hver sin tabel:

SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori, tekster.Toverskrift FROM kategorier INNER JOIN tekster ON kategorier.TKID=tekster.Tkatagori ORDER BY kategorier.TKID ASC"



Du kan rette denne linje:
response.write "<tr><td>TKID:" & rs("TKID") & "</td></tr>"

Til:
response.write "<tr><td>" & rs("TKoverskrift") & "</td></tr>"


Samt rette denne linje:
  response.write "<tr><td>-Tkategori=" & rs("Tkatagori") & "</td></tr>"

Til:
  response.write "<tr><td>-" & rs("Toverskrift") & "</td></tr>"

helt perfekt!!

hvordan få jeg den til at være 100% bred samt at alt tekst i cellerne altid står øverest!

tak!

Prøv med dette :


lastID = ""
response.write "<table width=""100%"">"
colPrRow = 0
maxPrRow = 2
do while not rs.EOF
  if colPrRow = 0 then Response.write "<tr>"

  if lastID <> rs("TKID") then
    Response.Write "<td valign=""top"">"
    response.write "<table width=""100%"">"
    response.write "<tr><td>" & rs("TKoverskrift") & "</td></tr>"
    lastID = rs("TKID")
    colPrRow = colPrRow + 1
  end if

  response.write "<tr><td>-" & rs("Toverskrift") & "</td></tr>"
 
  rs.Movenext

  if not rs.EOF then
    if lastID <> rs("TKID") then
      Response.Write "</table>"
      Response.Write "</td>"
    end if
  else
    Response.Write "</table>"
    Response.Write "</td>"
  end if

  if colPrRow = maxPrRow then
    colPrRow = 0
    response.write "</tr>"
  end if
loop
if colPrRow > 0 then response.write "</tr>"
response.write "</table>"
%>

Du er kongen!! tak skal du have!!!

UPS! jeg har fundet en lille mangel, hvis vi kan nå at rette den??

Hvis der ikke er nogle underkategorier i nogle af kategorierne, bliver kategorierne ikke vist! hvordan kan man gøre det således at de også bliver vist hvis der ikke er underkategorier!!

Så prøv at rette i SQL sætningen: 
INNER JOIN

Til:
LEFT JOIN

så skulle medtage alle også selvom der ikke er nogle underkategorier..:

SQL = "SELECT kategorier.TKID, kategorier.TKoverskrift, tekster.Tkatagori, tekster.Toverskrift FROM kategorier LEFT JOIN tekster ON kategorier.TKID=tekster.Tkatagori ORDER BY kategorier.TKID ASC"

tak skal du have!!