download fil - gem i bestemt bibliotek

Mener det her virker:

uses wininet;

function GetInetFile(const fileURL, FileName: String): boolean;
const BufferSize = 1024;
var
  hSession, hURL: HInternet;
  Buffer: array[1..BufferSize] of Byte;
  BufferLen: DWORD;
  f: File;
  sAppName: string;
begin
Result:=False;
sAppName := ExtractFileName(Application.ExeName);
hSession := InternetOpen(PChar(sAppName),INTERNET_OPEN_TYPE_PRECONFIG,nil, nil, 0);
try
  hURL := InternetOpenURL(hSession,PChar(fileURL),nil,0,0,0);
  try
  AssignFile(f, FileName);
  Rewrite(f,1);
  repeat
    InternetReadFile(hURL, @Buffer,SizeOf(Buffer), BufferLen);
    BlockWrite(f, Buffer, BufferLen)
  until BufferLen = 0;
  CloseFile(f);
  Result:=True;
  finally
  InternetCloseHandle(hURL)
  end
finally
  InternetCloseHandle(hSession)
end
end;

Du kan bruge det sådan:

procedure TForm1.Button1Click(Sender: TObject);
begin
GetInetFile('http://www.eksperten.dk/img/eksperten_logo_new.gif','c:\1.gif');
end;

Eller sådan her:

uses Urlmon;

procedure DownloadFile(const URL: string; Filename: string);
begin
URLDownloadToFile(nil,PChar(URL),PChar(filename),0,nil);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
DownloadFile('http://www.eksperten.dk/img/eksperten_logo_new.gif', 'c:\1.gif');
end;