Valutakurser - automatisk opdatering

Du kan vis XMLHTTP nakke kurserne fra www.valutakurser.dk ;-)

Heh, det er nok ik helt lovligt, og desuden ved jeg ikke hvordan man gør :)

hmm.. kan ikke finde deres nye copyright.. men deres gamle er:

Copyright © 2003 Euroinvestor.com A/S.
Alle rettigheder forbeholdes.
Indholdet på siden videregives uden ansvar for fejl og mangler.

Well .. nu har jeg fundet denne XML fil: http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml

Den kan jo bruges, og den er lagt til fri afbenyttelse fra den Europæiske Centrabank. Jeg ved bare ikke hvordan jeg henter indholdet af den fra en ASP-side og parser den derfra .. er det noget du kan hjælpe mig med? :)

Jeg tror godt at det kan la' sig gøre :)
..kigger lige på det..

Så er jeg klar.. smider lige noget kommentar-halløj i koden.. :)

Det lyder godt .. jeg venter spændt :)

Hvis scriptet skal udbygges/ændres, siger du bare til.

<%
Option Explicit ' alle variabler SKAL defineres/dim(mes).. skal man altid huske
Response.Buffer = true ' hele siden genereres før den sendes til browseren

Dim objXMLHTTP, xml, url, html ' dimme dimme dimme..

' XMLHTTP object oprettes:
Set xml = Server.CreateObject("Microsoft.XMLHTTP")

' vores url:
url = "http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml"

' Åben forbindelsen til urlen:
xml.Open "GET", url, False

' sender kommandoen og henter resultatet:
xml.Send

' Smider resultatet over i variable "html":
html = xml.responseText

Set xml = Nothing ' destruer objeckt "xml" for at frigør resourcer på server.. skal man altid huske..


dim i
dim arrHTML, arrCode, arrValue
dim code, value
dim posstart, posend

html = mid(html, inStr(html, "<Cube currency=")) ' beskær data så vi kun har det vi skal bruge

code = "": value = "" ' sørge for at disse variabler er tomme.. behøves egentlig ikke :)

arrHTML = split(html, "<Cube currency='") ' splitte data fra "html" ved "<Cube currency='", så vi har en array

for i = LBound(arrHTML) to UBound(arrHTML) ' looper fra lavest værdi til højeste værdi
if left(arrHTML(i), 1) <> "" then ' koden skal kun afvikles hvis linien IKKE er tom

  posstart = inStr(arrHTML(i), "rate='") + 6 ' start position for vores data
  posend = inStr(arrHTML(i), "'/") - 1 ' slut position for vores data

  code = code & left(arrHTML(i), 3) & ";" ' her samles koderne og adskelles af ";", til senere brug (array)
  value = value & mid( arrHTML(i), posstart, posend - posstart) & ";" ' her samles koderne og adskelles af ";", til senere brug (array)

end if
next

arrCode = split(code, ";") ' her splittes koderne ved ";", så har vi en array
arrValue = split(value, ";") ' her splittes koderne ved ";", så har vi en array

' Her er en loop der udskriver alle koderne og værdierne..

for i = LBound(arrCode) to Ubound(arrCode) - 1
  response.write arrCode(i) & ": " & arrValue(i) & "<br>" & vbCrLf
next
%>

Det fungerer :) Lækkert nok .. Hvis du lægger et svar, kan du også få point! ;)

Et svar er lagt :)

Et svar er accepteret :)

hehe.. tak for points :-)