Sende en mail med indholdet som en attached csv fil

Dan CSV filen og gem den på severen, vedhæft den som attachment til emailen, send den og slet filen igen. Jeg går ud fra dat ligger i en database:

Her er lidt at arbejde videre med - du ved nok bedst, hvordan du hefter attachment på din emails:

<%

sub table2CSV(outputquery, outputDSN, filename,delim )
  dim conntemp, rstemp, linetxt
  set conntemp=server.createobject("adodb.connection")
  ' 0 sekunder betyder vent forever, default er 15
  conntemp.connectiontimeout=0
  conntemp.open outputDSN
  set rstemp=conntemp.execute(outputquery)
  howmanyfields=rstemp.fields.count -1
      Set fs = CreateObject("Scripting.FileSystemObject")
    'Set file = fs.OpenTextFile(server.mappath(filename), 8, True, False)
    Set file = fs.CreateTextFile(server.mappath(filename))
  linetxt=""
  if isnull(delim) then
    delim=";"
  end if
  for i=0 to howmanyfields-1
    linetxt = linetxt & rstemp(i).name & delim
  next
    linetxt = linetxt & rstemp(i).name
    file.Writeline(linetxt)
 
 
  DO UNTIL rstemp.eof
        linetxt=""
       
        for i = 0 to howmanyfields-1
            thisvalue=rstemp(i)
            If isnull(thisvalue) then
                thisvalue=" "
            end if
            linetxt = linetxt & thisvalue & delim
        next
        thisvalue=rstemp(i)
   
        If isnull(thisvalue) then
            thisvalue=" "
        end if
   
        linetxt = linetxt & thisvalue
   
        'lad os fjerne de linefeeds
        linetxt=Replace(linetxt, vbcrlf, " ")
   
        file.Writeline(linetxt)
        rstemp.movenext

    loop
    file.close
    set file=nothing
    Set fs=nothing
    rstemp.close
    set rstemp=nothing
    conntemp.close
    set conntemp=nothing
end sub
sub delCSV(filename)
    Set fs = CreateObject("Scripting.FileSystemObject")
   
   
    if fs.FileExists(server.mappath(filename)) then
        Set file = fs.GetFile(server.mappath(filename))
        file.Delete
        if not fs.FileExists(server.mappath(filename)) then
            response.write filename & " er nu slettet <br>"
        else
            response.write filename & " blev ikke slettet <br>"
        end if
    else
        response.write filename & " er ikke tilstede <br>"
    end if
    set file=nothing
    Set fs=nothing
end sub
%>

John - lukker du sagen ?

Henrik, skriver du ikke lige en mail til mig på john@spritelab.dk, jeg har en opgave hvis du er interesseret...