Ja helt sikkert.
Det der sker på login.asp, er at UserID fra databasen huskes i Session("UserID"). Jeg går udfra at UserID er den unikke nøgle i tabellen, det som jeg kaldte ID tidligere.
Hvis du vil have Fornavn og efternavn, så gøre du det præcis som du gør i det første tilfælde, blot siger den:
Com.Commandtext = "SELECT Fornavn, Efternavn FROM Users WHERE UserID = " & Session("UserID")
Men jeg har et bedre forslag; du kan gemme fornavn/efternavne i Session-variabler ligesom du gør med UserID. Så har du dem klar på alle dine sider, uden at skulle åbne databasen blot for det.
Så i login.asp gør du dette;
<%
' Hvis der er blevet trykket på knappen "Login"
If Request.Form("Action") = "Login" Then
' Her forberedes de indtastede værdier til validering
strUID = Trim(Replace(Request.Form("Brugernavn"),"'",""))
strPWD = Trim(Replace(Request.Form("Adgangskode"),"'",""))
' Hvis der er skrevet noget i både brugernavn og adgangskode
If Len(strUID) > 0 And Len(strPWD) > 0 Then
' DSNLess forbindelse til databasen
Set myConn = Server.CreateObject("ADODB.Connection")
myConn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("db/db.mdb")
' Opbygning af SQL streng
strSQL = "SELECT UserID, Fornavn, Efternavn FROM Users"&_
" WHERE (Username = '" & strUID & "')"&_
" AND (Password = '" & strPWD & "')"
Set rs = myConn.Execute(strSQL)
If Not (rs.BOF Or rs.EOF) Then
' Hvis brugeren fandtes i databasen
intUID = rs("UserID")
Session("Fornavn") = rs("Fornavn")
Session("Efternavn") = rs("Efternavn")
Else
' Hvis brugeren ikke fandtes i databasen
strERR = "Du blev ikke godkendt af systemet"
End If
' Rydder op i vores connection objekt
myConn.Close
Set myConn = Nothing
If Len(intUID) Then
' Hvis variablen intUID indeholder en værdi sættes denne i sessionen "UserID" og brugeren bliver sendt videre
Session("UserID") = intUID
Response.Redirect("beskyttet.asp")
End If
Else
' Hvis der ikke var angivet brugernavn og adgangskode
strErr = "Du skal skrive både brugernavn og adgangskode"
End If
If Len(strErr) > 0 Then
' Her laves fejlmeddelsen om til rød skrift
strErr = "<p><font color=red>" & strErr & "</font></p>"
End If
End If
%>
<html><head>
<title>Login script</title>
</head><body>
<form method="POST" action="login.asp">
<p><font size="4">Angiv brugernavn og adgangskode</font></p><%=strErr%>
<table border="0">
<tr>
<td width="50%">Brugernavn:</td>
<td width="50%"><input type="text" name="Brugernavn" size="20"></td>
</tr>
<tr>
<td width="50%">Adgangskode:</td>
<td width="50%"><input type="password" name="Adgangskode" size="20"></td>
</tr>
</table>
<p><input type="submit" value="Login" name="Action"></p>
</form>
</body></html>
