Tælle antal værdier i område

=TÆL("celler")

celler kan godt være flere usammenhængende områder i flere kolonner

Desværre giver det ikke det ønskede resultat.
Jeg går ud fra at TÆL er lig med COUNT på engelsk.
Hvis der står noget i flere felter i en linie tælles de med som flere og det er det der er hele humlen i det.

Prøv at gøre følgende:

Lav en hjælpekolonne, f.eks. kolonne D, hvor du i D1 skriver følgende:
=HVIS(SUM(A1:C1)>0;1;0)

Kopier formlen ned, så længe der er data.

I bunden i kolonne D laver du så en SUM-formel, f.eks. =SUM(D1:D999)

Denne sum giver dig tallet for, hvor mange rækker der er tal i større end nul, og hver række bliver kun talt med én gang.

=COUNTIF(D8:I25;">0")

janvogt>  det ville jeg helst undgå, men kan det ikke laves uden hjælpekolonner, så må jeg jo krybe til korset.

Flemming, man kan ikke bruge en almindelig tælle-formel, for hver række i området må kun tælles med én gang.

Har vist misforstået noget.......

Hugo, du kan jo altid skjule hjælpekolonnen igen.

janvogt>  det har du selvfølgelig ret i men da det drejer sig om 12 seperate områder, ville jeg gerne undgå det :-)

Indsæt følgende makro i et almindeligt kodemodul:

Public Function CountSpecial(ByVal rCells As Range) As Long
    Dim rCell As Range
    Dim colRow As New Collection
   
    On Error Resume Next
    For Each rCell In rCells
        If rCell.Value Then colRow.Add rCell.Row, CStr(rCell.Row)
    Next rCell
    On Error GoTo 0
   
    CountSpecial = colRow.Count
End Function

i en celle skriver du f.eks.
=countspecial(D6:F12)

Hvis du har ét eller andet, som kendetegner om rækken skal tælles med eller ej, kunne du udvide HVIS-formlen, f.eks. sådan

=HVIS(A1="";"";HVIS(SUM(B1:D1)>0;1;0))

Så kunne du måske tage højde for, at der er flere områder.

Flemming, hvad hvis der er flere områder?

Ikke noget problem, bare der ikke er rækkeoverlap

Men det kan vel lige laves *gg*

jeg ville nu osse bruge janvogts løsning med en hjælpekolonne. Og så skjule den efterfølgende.

Men er der også negative tal, skal du nok gribe formlen lidt anderledes an:
=HVIS(OG(ER.TOM(celle1);ER.TOM(celle2);ER.TOM(celle3));0;1)

min formel undersøger, om alle cellerne er tomme. Hvis de er, bliver værdien nul, ellers 1.

Godt set med de negative tal B_hansen :-)

Det tager Flemmings funktion nu også højde for.

Public Function CountSpecial(ByVal sCells As String) As Long
    Application.Volatile
    Dim lRetVal As Long
    Dim rCell As Range
    Dim colRow As Collection
    Dim sSplit() As String
    Dim lSplit As Long
   
    lRetVal = 0
    sCells = Replace(sCells, ",", ";")
    sSplit() = Split(sCells, ";")
   
    For lSplit = 0 To UBound(sSplit)
        On Error Resume Next
       
        Set colRow = New Collection
       
        For Each rCell In Range(sSplit(lSplit))
            If rCell.Value Then colRow.Add rCell.Row, CStr(rCell.Row)
        Next rCell
       
        lRetVal = lRetVal + colRow.Count
       
        On Error GoTo 0
    Next lSplit
   
    CountSpecial = lRetVal
End Function

I cellen  =CountSpecial("D7:F15;I11:L19")  (noter at det er en string og ikke et direkte område...!

Flot Flemming ;-)

flemmingdahl> din funktion er 'købt' - it does the trick

Det skal bruges til en kalender til beregning af kørselsfradrag hvor jeg indtaster km i rækkerne og skal tælle antal dage hvor der er kørt for at kunne regne videre.

god fornøjelse Hugo og tak Jan :-)

Skal det være godt, så skal det være rigtig godt

Public Function CountSpecial( _
    ByVal sCells As String, _
    ByVal bAsOneArea As Boolean _
    ) As Long
   
    Application.Volatile
    Dim lRetVal As Long
    Dim rCell As Range
    Dim colRow As New Collection
    Dim sSplit() As String
    Dim lSplit As Long
   
    lRetVal = 0
    sCells = Replace(sCells, ",", ";")
    sSplit() = Split(sCells, ";")
   
    If Not (bAsOneArea) Then Set colRow = New Collection
    For lSplit = 0 To UBound(sSplit)
        On Error Resume Next
       
        If bAsOneArea Then Set colRow = New Collection
       
        For Each rCell In Range(sSplit(lSplit))
            If rCell.Value Then colRow.Add rCell.Row, CStr(rCell.Row)
        Next rCell
       
        If bAsOneArea Then lRetVal = lRetVal + colRow.Count
       
        On Error GoTo 0
    Next lSplit
   
    If Not (bAsOneArea) Then lRetVal = colRow.Count
   
    CountSpecial = lRetVal
End Function

Alle de forskellige områder som et område:
=countspecial("E10:G18;I14:K22";TRUE)
som flere områder:
=countspecial("E10:G18;I14:K22";FALSE)

Det skulle lige vendes rundt - her er den helt rigtige

Public Function CountSpecial( _
    ByVal sCells As String, _
    ByVal bAsOneArea As Boolean _
    ) As Long
   
    Application.Volatile
    Dim lRetVal As Long
    Dim rCell As Range
    Dim colRow As New Collection
    Dim sSplit() As String
    Dim lSplit As Long
   
    lRetVal = 0
    sCells = Replace(sCells, ",", ";")
    sSplit() = Split(sCells, ";")
   
    If bAsOneArea Then Set colRow = New Collection
    For lSplit = 0 To UBound(sSplit)
        On Error Resume Next
       
        If Not (bAsOneArea) Then Set colRow = New Collection
       
        For Each rCell In Range(sSplit(lSplit))
            If rCell.Value Then colRow.Add rCell.Row, CStr(rCell.Row)
        Next rCell
       
        If Not (bAsOneArea) Then lRetVal = lRetVal + colRow.Count
       
        On Error GoTo 0
    Next lSplit
   
    If bAsOneArea Then lRetVal = colRow.Count
   
    CountSpecial = lRetVal
End Function

Flemming, hvori består forskellen, om det behandles som ét eller flere områder?

bAsOneArea = True
Hvis der er flere områder, med overlappende rækkenr, så tælles rækken kun med EN gang

bAsOneArea = False
En række kan tælles med flere gange, hvis den optræder i flere områder

en lille array formel kan måske også gøre det:

=SUM(IF(SUMIF(OFFSET(B1:E1;ROW(1:100)-1;;;);"<>0")>0;1))

tæller i kolonne B:E række 1:100

Jeg kan også godt lide flemmings model og helt specielt brugen af Collection for at sikre at kun unikke rækker tælles :-)

Bak, den brugte jeg ½ time på at "opfinde" - uden held :-)

Der er dog et minus - den tager ikke højde for negative værdier.

antal kørte km kan vel ikke være negativ :-)

med mindre du er brugtvognsforhandler....

Med en mindre korrektion ser det ud til at gå fint
=SUM(IF(SUMIF(OFFSET(B1:AA1;ROW(1:100)-1;;;);"<>0")<>0;1))

Hehe, ja, det har du ret i.
Når man studerer et problem glemmer man ofte den oprindelige problemstilling :-)

Jeg ved ikke rigtigt, om jeg kan lide din sidste løsning. Du fjernede problemet, men skabte et nyt :-)

jeps, du har ret Jan, den oprindelige er bedst.