At nulstille en database

Hvis det er en Access database, så slet alle records og så vælg Funktioner > Databasefunktioner > Komprimér og reparer database.

/Goose

GOOSE

Det er en Access Database men da jeg har lavet dette spm i ASP så ønsker jeg en løsning i dette sprog. hvis der findes en !!

Okay, hvis du kan finde ud af at tømme alle data fra databasen med:

"delete * from [TABEL] where id > 0"

- og så bruge den her til at komprimerer den med:
http://www.dotnetindex.com/articles/59

/Goose

okay ser meget OK ud.

hvis jeg nu giver dig mine database oplysninger vil du så evt lave et test script til den !??

test.mdb
test
ID = Auto/Key
TITLE = Text
TEXT = Text

Prøv nedenstående, dog skal du lige rette stien til databasen til den der gælder for dit webhotel (DBQ=d:\web\domæne.dk\www\log\database\test.mdb)

Jeg har lige testet på min egen server og det virker ok.


<%
response.buffer = true
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=d:\web\domæne.dk\www\log\database\test.mdb"

' ***********************************************************
' SLET ALT I TABELLEN
' ***********************************************************

SQL = "delete * from test where id >0"
conn.execute(SQL)
conn.close
set conn = nothing

' ***********************************************************
' KOMPRIMER DATABASEN
' ***********************************************************


  oldFile = "d:\web\domæne.dk\www\log\database\test.mdb"
  newFile = "d:\web\domæne.dk\www\log\database\temp_backup.mdb"

  strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="& oldFile
  strConnBak = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & newFile
   
  Set objJRO = Server.CreateObject("JRO.JetEngine")
  objJRO.CompactDatabase strConn, strConnBak
  Set objJRO = Nothing

  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  If objFSO.FileExists(newFile) And objFSO.FileExists(oldFile) Then
  objFSO.DeleteFile(oldFile)
  objFSO.MoveFile newFile, oldFile
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation udført.</font>"
  Else
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation mislykkedes !!!</font>"
  End If

  Set objFSO = Nothing
  %>

/Goose

jeg hader drev bogstaver ;) kan jeg ikke bare lave det til en mappe så jeg evt bare har database\test.mdb !?? eller !?

<%
response.buffer = true

' ***********************************************************
' SLET ALT I TABELLEN
' ***********************************************************

strCon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("database/test.mdb")
Set con = server.createobject("adodb.connection")
con.open strCon
SQL = "delete * from test where id >0"
con.execute SQL
con.close
set con = nothing


' ***********************************************************
' KOMPRIMER DATABASEN
' ***********************************************************

oldFile = Server.MapPath("database/test.mdb")
newFile = Server.MapPath("database/backup_test.mdb")

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="& oldFile
strConnBak = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & newFile

  Set objJRO = Server.CreateObject("JRO.JetEngine")
  objJRO.CompactDatabase strConn, strConnBak
  Set objJRO = Nothing

  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  If objFSO.FileExists(newFile) And objFSO.FileExists(oldFile) Then
  objFSO.DeleteFile(oldFile)
  objFSO.MoveFile newFile, oldFile
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation udført.</font>"
  Else
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation mislykkedes !!!</font>"
  End If

  Set objFSO = Nothing
  %>

/Goose

Okay den virker jo kanon MEN den loader halvt og så står den ellers bare der og loader og der sker intet men den har oprettet en TOM backup og tømt den oprindelige men har ikke komprimeret den så den er ligeså stor/LILLE som backuppen.

så jeg tænkte på om man ikke kunne gøre så den backup der bliver lavet overskriver den oprindelige og om den så vilel loade færdig og sige at komprimeringen er udført eller !??

Ved ikke hvorfor det ikke virker hos dig, jeg har testet på min server og der virker det fint ?
Du tror ikke det er din server der hænger ?!?

/Goose

okay kan det være fordi jeg køre det på en IIS !?

Ja det kan det godt, du skal ihvertfald bruge MDAC 2.1 for at det virker har jeg læst, det er først fra den version at CompactDatabase virker.

Har du ikke mulighed for at teste på et webhotel ?!?

/Goose

hvordan kan jeg updaterer til den nyeste MDAC !?

jo men jeg har uploadet det men skal vente på at de laver skriverettigheder til min mappe !! :)

Aner det ikke.

Har du virkelig ikke en mappe på din server hvor du har skriverettigheder ?

/Goose

nej for jeg har ikke uploadet mit site endnu da det ikek er færdigt

men fandt og installerede MDAC 2.8 så ser lige om det virker på min IIS

når så fik jeg skrive rettigheder og det virker jo kanon hurtigt under 1 sek. at gøre det den skal og så sletter den endda 120 recorder osv...

Mange tak du :D

LIGE EN TING

hvis jeg har en database på 4.5 Mb og jeg har slettet en del i den så jeg ved den kan blive mindre ved at komprimerer den så skal jeg da kun/bare bruge dette stykke af din code ikke !??

<%
' ***********************************************************
' KOMPRIMER DATABASEN
' ***********************************************************

oldFile = Server.MapPath("database/test.mdb")
newFile = Server.MapPath("database/backup_test.mdb")

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="& oldFile
strConnBak = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & newFile

  Set objJRO = Server.CreateObject("JRO.JetEngine")
  objJRO.CompactDatabase strConn, strConnBak
  Set objJRO = Nothing

  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  If objFSO.FileExists(newFile) And objFSO.FileExists(oldFile) Then
  objFSO.DeleteFile(oldFile)
  objFSO.MoveFile newFile, oldFile
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation udført.</font>"
  Else
  Response.Write "<font size=""+2"" color=""crimson"">Komprimering og reparation mislykkedes !!!</font>"
  End If

  Set objFSO = Nothing
  %>

!??

Tak for point og ja, så skal du bare bruge komprimeringsdelen.

/Goose

manga tak du.