Add button via VBA til excelsheet

er selv igang med at kigge på
http://www.eksperten.dk/spm/342573

hvor Bak omtaler VBIDE, da det skal bruges i processen, og der garanteret er noget i spørgsmålets kommentarer, der kan hjælpe mig videre...

Noget i retning af
Sub Makro1()
    Application.CommandBars("Control Toolbox").Visible = True
    ActiveSheet.OLEObjects.Add(ClassType:="Forms.CommandButton.1", Link:=False _
        , DisplayAsIcon:=False, Left:=161.25, Top:=100.5, Width:=72, Height:= _
        24).Select
    Selection.ShapeRange.Left = Range("b7").Left
    Selection.ShapeRange.Top = Range("b7").Top
    Selection.ShapeRange.width= Range("b7").Width
    Selection.ShapeRange.height= Range("b7").height

End Sub

Knappen lægger sig i B7

Linien
    Application.CommandBars("Control Toolbox").Visible = True
kan udelades, den kom med da jeg indspillede makroen
Tilføj
Selection.ShapeRange.Name = "Test" ' eller et andet navn

Jeg er lidt i tvivl om hvordan du får tilknyttet den rigtige procedure til din knap, men følgende procedure på den relevante ark bliver kaldt

Private Sub Test_Click()
    MsgBox "Hej"
End Sub

Baks kode kan sikkert bruges, men husk at bruge "Shaperange"-object og ikke "Forms", da du skal have knappen liggende i en celle

Hej og tak Stefanfuglsang,
Lige før jeg giver pointene - jeg ved godt at det er lidt ud over det oprindelige spm, men har du også lige et forslag til, hvordan jeg så bruger knappen til at kalde en public sub med fx A7 som input?

Jeg kan godt følge dig, Stefan, men jeg vil gerne forsøge at undgå "selection", hvilket vil sige at jeg anvender dit input vedr. placeringen, men opretter det som brynil indleder spm http://www.eksperten.dk/spm/342573

Men du får pointene for at lede mig i den rigtige retning! :-)

Jeg må nok hellere oprette et andet spm til problemstillingen med at håndtere det bagvedliggende procedurekald, som er mere i stil med VBIDE...

Denne opretter en knap på det aktive ark i kolonne B i samme række som den aktive celle og den tilhørende kode, som så refererer til samme rækkes kolonne A.
Dvs at den kalder en public sub Testing med kolonne A's adresse.

Sub AddProcedure()

Dim VBCodeMod As CodeModule
Dim Line As Long, t As Single, l As Single
Dim SheetName As String, SheetCodeName As String
Dim Knap As OLEObject

Application.ScreenUpdating = False

SheetName = "Ark1"
SheetCodeName = Sheets(SheetName).CodeName
t = ActiveCell.Top
l = Columns(2).Left
Set Knap = ThisWorkbook.Sheets(SheetName).OLEObjects.Add(ClassType:="Forms.CommandButton.1", Link:=False _
        , DisplayAsIcon:=False, Left:=l, Top:=t, Width:=131.25, Height _
        :=27.75)
Knap.Name = "cmdGemNavn" & CStr(ActiveCell.Row)
Knap.Object.Caption = "Vis noget"

Set VBCodeMod = ThisWorkbook.VBProject.VBComponents(SheetCodeName).CodeModule

With VBCodeMod
    Line = .CreateEventProc("Click", Knap.Name)
    .InsertLines Line + 2, "call testing(""" & Cells(ActiveCell.Row, 1).Address & """)"
End With
Application.VBE.MainWindow.Visible = False

Application.ScreenUpdating = True
End Sub

Sub testing(t As String)
MsgBox t
End Sub