en af de svære

Jeg er ikke helt sikker, men i det følgende har blot brugt sum.hvis funktionen, til det jeg tror, du vil have (hvis du forstår) :0)

=SUM.HVIS(A1:A365;"<"&D2;B1:B365)-SUM.HVIS(A1:A365;"<"&D1;B1:B365)

Datoer står i A1:A365.
"Maskintiden" står i B1:B365
Ønsket startdato står i D1
Ønsket slutdato står i D2

En anden måde at gøre det samme på er at bruge sumprodukt-funktionen:

=SUMPRODUKT((A1:A365>=D1)*(A1:A365<D2)*B1:B365)

Cellerne gælder som i ovenstående kommentar.

Hej sjap

desværre er det ikke lige så nemt da dataerne ikke står på denne måde. Der er mange flere dataer i boksen, så jeg kan ikke bruge kolonne funktionen ?

>sjap

kan jeg sende en kopi til dig så du kan se opstillingen ?

Nej, det er det selvfølgelig ikke. Så havde det jo været for nemt i forhold til alle de point du har udlovet. Men det var da forsøget værd. ;0)

Send fil til sjap9000 snabel hotmail punktum com så skal jeg se, hvad jeg kan gøre.

Med din opstilling er det ret håbløst at bruge de almindelige opslagsfunktioner. I stedet har jeg førsøgt at lave en "manuel" sum, som relativ let kan kopieres - DOG MED MINDRE BEGRÆNSNINGER.

For det første laves en funktion, der finde hvilken række den første dato står i:

=SAMMENLIGN(E2;'2004'!D:D;1)+2

I det følgende forudsætte den placeret i AE1. Den leder i hele kolonne D i fanebladet 2004. Datoen står to rækker over de første data, så derfor lægges 2 til tallet (mere om det senere).

I celle AE2 skriver du 20 (antallet af rækker mellem 2 "bokse" i "2004").

Dernæst kan du kopiere nedenstående funktion ind i din celle D6 (på fanebladet "Ugens samlede resultat"):

=INDIREKTE("'2004'!R["&$AE$1-6&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+$AE$2&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+2*$AE$2&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+3*$AE$2&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+4*$AE$2&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+5*$AE$2&"]C[1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+6*$AE$2&"]C[1]";FALSK)

Den se umiddelbart lidt frygtelig ud, men den er faktisk ikke så slem. Der står bare næsten det samme 7 gange. Så lad os et øjeblik blot se på den første del:

=INDIREKTE("'2004'!R["&$AE$1-6&"]C[1]";FALSK)

Funktionen INDIREKTE bruges til at ændre referencen til en celle uden at ændre formlen. I dette tilfælde laves en reference til fanebladet "2004".

FALSK betyder at der anvendes relative referencer (se evt. i hjælpen under R1C1). Det betyder blot at hvis formlen f.eks. står i D6 (f.eks. på fanebladet "Ugens samlede resultat"), og den celle du vil pege på er E25 (på fanebladet "2004"), så vil den relative reference være

'2004'!R[19]C[1]

Det betyder at du skal 19 rækker længere ned end den du står i (du står i række 6, og 25-6=19), og du skal 1 kolonne til højre (fra D til E).

Hvis vi kigger på en del af det, der lave referencen, så ser det således ud:

$AE$1-6

i $AE$1 står der i hvilken række startdatoen findes. Det skal være en relativ reference, så der skal fratrækkes 6 rækker (de første data skal placeres i række 6 i "Ugens samlede resultat").

Sådan er grundprincippet for at pege på den første dag du leder efter. For at finde de følgende 7 dage laves en tilsvarende formel for hver dag, der så skal pege nogen rækker længere ned i regnearket. Her er f.eks. den, der skal hente data for dag 7:

+INDIREKTE("'2004'!R["&$AE$1-6+6*$AE$2&"]C[1]";FALSK)

Den vigtigste forskel er i beregningen af referencen:

$AE$1-6+6*$AE$2

Du har skrevet 20 i AE2, for det er antallet af rækker mellem 2 dage på fanebladet "2004". De 20 skal ganges med 6 for at komme 7 dage ned (den første dag svarer jo til at gange med 0).

Det gælder om at holde tungen lige i munden, men formlen virker, og du kan uden videre kopiere den til cellerne i kolonne D og E på fanebladet "Ugens samlede resultat".

For at kopiere formlen til de resterende faneblade skal du lige tænke på, at der i fanebladet "Ugens samlede resultat" er flere kolonner end i "2004". Så når du kopierer, sker der en forskydning, der ikke bliver taget højde for, og som du så er nødt til at ændre manuelt.

Du kan kopiere formlen til J6, hvor du så skal ændre C[1] til C[-1] alle 7 steder i formlen. Dereften kan den uden videre kopieres til cellerne i kolonne J og L. Formlen skulle gerne se således ud:

=INDIREKTE("'2004'!R["&$AE$1-6&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+$AE$2&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+2*$AE$2&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+3*$AE$2&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+4*$AE$2&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+5*$AE$2&"]C[-1]";FALSK)
+INDIREKTE("'2004'!R["&$AE$1-6+6*$AE$2&"]C[-1]";FALSK)

Du kan kopiere formlen til P6, hvor du så skal ændre C[-1] til C[-3] alle 7 steder i formlen. Dereften kan den uden videre kopieres til cellerne i kolonne P og R.

Du kan kopiere formlen til V6, hvor du så skal ændre C[-1] til C[-5] alle 7 steder i formlen. Dereften kan den uden videre kopieres til cellerne i kolonne V og X.

Det er nok det rene volapyk, men jeg returnerer lige dit regneark, så hjælper det måske.

>sjap

Jeg må sige at jeg er vildt imponeret. Det er s.. fantastisk.

Jeg takker.

Håber du kan bruge det - og ikke mindst forstå, hvad jeg fik skrevet her ovenfor :0)