Korrekt dato / dato validering - ASP/MySQL

Var det ikke smartere at lave datovalget som tre select-bokse. En til hver: dag, måned, år?

jo, men nu er udfordringen en lidt anden jvf. spørgsmålet.

Er den en sikker måde at lave dato validering på ved 'ukendte' formater ?

Ja det er jeg klar over, men det kunne jo være det andet ikke have strejfet dig.

Du kan jo lave et regexp, javascript for direkte validering eller asp hvor den submitter  og først derefter svarer om det er valid.

Regulære udtryk er godt. Men der er et problem mellem dansk og udansk skrivemåde.
Betyder "11-12-2004" nu 11. december eller 12. november? Hvis du kan bestemme dig
for det, kan det nok grejes ;)

Du kan jo lege lidt med dette eksempel. Det kunne nok laves en anelse smarter,
men regulære udtryk i stenalder-ASP er ret kluntede, desværre.

<%

  function two(s)
    if len(s)=1 then
      two="0" & s
    else
      two=s
    end if
  end function

  function datotjek(dato)
    dim regex,matches,match
    set regex = new regexp
    regex.pattern = "^ *([0-9]{4})-([0-9]{1,2})-([0-9]{1,2}) *$"
    regex.global = false
    regex.ignorecase = false

    set matches = regex.execute(dato)

    if matches.count>0 then
      set match=matches(0)
      datotjek=match.submatches(0) & "-" & two(match.submatches(1)) & "-" & two(match.submatches(2))
      set matches=nothing
      exit function
    end if
    set matches=nothing

    regex.pattern = "^ *([0-9]{4})([0-9]{2})([0-9]{2}) *$"

    set matches = regex.execute(dato)

    if matches.count>0 then
      set match=matches(0)
      datotjek=match.submatches(0) & "-" & two(match.submatches(1)) & "-" & two(match.submatches(2))
      set matches=nothing
      exit function
    end if
    set matches=nothing

    regex.pattern = "^ *([0-9]{1,2})-?([0-9]{1,2})-([0-9]{4}) *$"

    set matches = regex.execute(dato)

    if matches.count>0 then
      set match=matches(0)
      datotjek=match.submatches(2) & "-" & two(match.submatches(1)) & "-" & two(match.submatches(0))
      set matches=nothing
      exit function
    end if
    set matches=nothing

    datotjek="FEJL"
  end function
 
  response.write datotjek("2004-06-01") & "<br>"
  response.write datotjek("  2004-6-1  ") & "<br>"
  response.write datotjek("  20040601  ") & "<br>"
  response.write datotjek("  1-6-2004  ") & "<br>"
  response.write datotjek("  øllebrød  ") & "<br>"

%>

Ups, den sidste skal ikke være
  regex.pattern = "^ *([0-9]{1,2})-?([0-9]{1,2})-([0-9]{4}) *$"
men
  regex.pattern = "^ *([0-9]{1,2})-([0-9]{1,2})-([0-9]{4}) *$"

Perfekt regexp.pattern var jo det jeg skulle bruge. (match.submatches er også smart.)

Jeg har udvidet scripet lidt så jeg også kan modtage årstal med kun 2 cifre.

Tak for hjælpen <erikjacobsen>, smider du et svar.

PS: Kender du en tutorial/artikel til dette emne ?

Jeg kender ikke noget rigtig godt online. Men der er skrevet bøger om det
som er gode. Søg selv ;)  Men der er fx den her:
http://www.whsmith.co.uk/WHS/Go.asp?isbn=1861007302&DB=220
(jeg kender den ikke)

Jeg samler ikke på point, tak.

Nu lukker jeg ved at tage dem tilbage.

Tak for hjælpen.