Hent oplysninger om computeren

Jeg ville nok hellere bruge Everest Home Edition

http://www.lavalys.com/products.php?lang=en

ja eller aida32 eller sandra

men jeg skal bruge det i excel ellers tak for hjælpen :)

http://xcelfiles.homestead.com/VBA_Quick.html
her er den opl. om computeren

og her lidt om diskene

Sub ShowDriveInfo()
    Dim FileSys, Drv
    Dim Row As Integer
   
    Set FileSys = CreateObject("Scripting.FileSystemObject")
    Cells.Clear
    Row = 0
    On Error Resume Next
    For Each Drv In FileSys.Drives
        Row = Row + 1
        Cells(Row, 1) = Drv.DriveLetter
        Cells(Row, 2) = Drv.IsReady
        Select Case Drv.DriveType
            Case 0: Cells(Row, 3) = "Unknown"
            Case 1: Cells(Row, 3) = "Removable"
            Case 2: Cells(Row, 3) = "Fixed"
            Case 3: Cells(Row, 3) = "Network"
            Case 4: Cells(Row, 3) = "CD-ROM"
            Case 5: Cells(Row, 3) = "RAM Disk"
        End Select
        Cells(Row, 4) = Drv.VolumeName
        Cells(Row, 5) = Drv.TotalSize
        Cells(Row, 6) = Drv.AvailableSpace
    Next Drv
End Sub

Hej bak

det er jo næsten helt perfekt :) hvordan får jeg oplysningerne listet i en kolonne

/srk

Det er de to jeg vil bruge ... men de returnere resultat i en "MsgBox" (mener jeg det hedder) hvordan får jeg det ned i nogle celler i stedet

http://www.xcelfiles.com/VBA_Quick5.html
http://www.xcelfiles.com/VBA_Quick4.html

Sub SysInfo()
Dim s As String
Dim oSystem As Object
Dim item As Object
Dim objWMI As Object
Dim Cpu As Object
Dim x As Long
    Set oSystem = GetObject("winmgmts:").instancesOf("Win32_ComputerSystem")
    Set objWMI = GetObject("WinMgmts:").instancesOf("Win32_Processor")
   
    '// Don't forget the computer maybe multiprocessor!
    For Each Cpu In objWMI
        x = x + 1
        Cells(x, 1) = LTrim(Cpu.Name)
        Cells(x, 2) = Cpu.CurrentClockSpeed & "Mhz"
    Next
   
    For Each item In oSystem
        x = x + 1
        Cells(x, 1) = "Navn"
        Cells(x, 2) = item.Name
        x = x + 1
        Cells(x, 1) = "Status: "
        Cells(x, 2) = item.Status
        x = x + 1
        Cells(x, 1) = "Type: "
        Cells(x, 2) = item.SystemType
        x = x + 1
        Cells(x, 1) = "Mfg: "
        Cells(x, 2) = item.Manufacturer
        x = x + 1
        Cells(x, 1) = "Model: "
        Cells(x, 2) = item.Model
        x = x + 1
        Cells(x, 1) = "RAM: "
        Cells(x, 2) = item.TotalPhysicalMemory \ 1024000 & "mb"
        x = x + 1
        Cells(x, 1) = "Domain: "
        Cells(x, 2) = item.Domain
        x = x + 1
        Cells(x, 1) = "Role: "
        Cells(x, 2) = TranslateDomainRole(item.DomainRole)
        x = x + 1
        Cells(x, 1) = "Current User: "
        Cells(x, 2) = item.UserName
    Next
    Set objWMI = Nothing
    Set oSystem = Nothing
End Sub

Function TranslateDomainRole(ByVal roleID) As String
Dim RetString As String
    Select Case roleID
        Case 0
            RetString = "Standalone Workstation"
        Case 1
            RetString = "Member Workstation"
        Case 2
            RetString = "Standalone Server"
        Case 3
            RetString = "Member Server"
        Case 4
            RetString = "Backup Domain Controller"
        Case 5
            RetString = "Primary Domain Controller"
        Case Else
            RetString = "Unknown"
    End Select
TranslateDomainRole = RetString
End Function

Mange tak for hjælpen :)