Header og footer skal ikke printes på side 1

Ikke umiddelbart, da et regneark ikke kan sektionsopdeles på samme måde som i Word.

Det vil være nemmest at lave side 1 som et selvstændigt dokument.

hans-jensen-> Det kan bare drille lidt i Excel, hvis data på side 1 skal hænge sammen med data på øvrige sider, via opslagsformeler osv.

Med en makro kan det godt gøres
Denne udskriver side 1 uden header/footers og resten med.

Sub FirstPageBlank()
Dim stLHead As String, stRHead As String, stCHead As String
Dim stLfoot As String, stCfoot As String, stRfoot As String

'Gem setup og nulstil header og footer
With ActiveSheet.PageSetup
    stLHead = .LeftHeader
    .LeftHeader = ""
    stCHead = .CenterHeader
    .CenterHeader = ""
    stRHead = .RightHeader
    .RightHeader = ""
    stLfoot = .LeftFooter
    .LeftFooter = ""
    stCfoot = .CenterFooter
    .CenterFooter = ""
    stRfoot = .RightFooter
    .RightFooter = ""
End With

'udskriv første side
ActiveWindow.SelectedSheets.PrintOut From:=1, To:=1

'indsæt den gemte opsætning med headers og footers
With ActiveSheet.PageSetup
    .LeftHeader = stLHead
    .CenterHeader = stCHead
    .RightHeader = stRHead
    .LeftFooter = stLfoot
    .CenterFooter = stCfoot
    .RightFooter = stRfoot
End With

'udskriv resten
ActiveWindow.SelectedSheets.PrintOut From:=2, To:=100
End Sub

Jamen, det var da dejligt! :-) Vil du så ikke svar, så at du kan få pointene?

ja, velbekomme