Windows XP Printers

Skal den samme printer tilføjes lokalt til hver PC eller taler vi om at tilføje en netværksprinter (ex. delt på server)?

... eller vil du blot tilføje driveren?

I så fald laver du et script, der kopierer driveren ud sammen med dine "andre drivere", ex. c:\drivers\printers\mappe

Herefter laver du et script, der henter nøglen fra registreringsdatabasen med stien til driverne og tilføjer ovenstående sti...

Vi taler selvfølgelig om en netværksdelt printer. Der er 5 lokaler med fem forskellige printere. Jeg vil gerne kunne køre det samme image ud på alle maskiner og derefter via fx et script tildele printeren til maskinen.

OK - du laver et login script som du tildeler hver bruger.

Jeg bruger selv Kixtart (www.kixtart.org).

Udpak kixtart og læg filerne (bl.a. kix32.exe mv.) i \\server\netlogon

I samme mappe laver du en fil, ex. printer.kix

Min fil ser således ud:

; *********************************************
; Sætter Variabler for Servere og Shares...
; *********************************************
  $NT1 = "ed1"


  Global $PrinterDel[20]
  Global $PrinterAdd[20]

  Function AddStringToArray($ArrName, $Str)
    If $ArrName = "Add"
      For $i=0 to UBound($PrinterAdd)
        If $PrinterAdd[$i]=""
          $PrinterAdd[$i]=$Str
          $i = UBound($PrinterAdd)+1
        Endif
      Next
    Else
      If $ArrName = "Del"
        For $i=0 to UBound($PrinterDel)
          If $PrinterDel[$i]=""
            $PrinterDel[$i]=$Str
            $i = UBound($PrinterDel)+1
          Endif
        Next
      Else
        ? "Wrong value of $ArrName passed to function AddStringToArray"
      Endif
    Endif 
  Endfunction

  Function AddPrinter($PrinterName)
    AddStringToArray("Add", $PrinterName)
  Endfunction

  Function DelPrinter($PrinterName)
    AddStringToArray("Del", $PrinterName)
  Endfunction

; DelPrinter("Konica 8031 PS v.1.1 eu")

AddPrinter("Konica 8031 PS v.2.0 EU")
AddPrinter("Konica 7040 PS Ver 2.02")
AddPrinter("OKI B4300")
AddPrinter("FieryX2e")

$PrinterAddErrorStr = "Fejl under tilføjelse af følgende printer(e):"
$FailedAddPrinters = ""

$PrinterDelErrorStr = "Fejl under fjernelse af følgende printer(e):"
$FailedDelPrinters = ""


? ""
For Each $Printer IN $PrinterDel
  If $Printer
    ? "Trying to delete " + $Printer
    If DELPRINTERCONNECTION ("\\" + $NT1 + "\" + $Printer) <> 0
      $FailedDelPrinters = $FailedDelPrinters + "\n  - " + $Printer
    Endif
  Endif
Next

? ""
For Each $Printer IN $PrinterAdd
  If $Printer
    ? "Trying to add " + $Printer
    If ADDPRINTERCONNECTION ("\\" + $NT1 + "\" + $Printer) <> 0
      $FailedAddPrinters = $FailedAddPrinters + "\n  - " + $Printer
    Endif
  Endif
Next

? ""
If $FailedDelPrinters
  ? $PrinterDelErrorStr
 
  $Myarray = Split("$FailedDelPrinters", "\n")
  For Each $Element In $MyArray
    ? $Element
  Next
Endif

? ""
If $FailedAddPrinters
  ? $PrinterAddErrorStr
 
  $Myarray = Split("$FailedAddPrinters", "\n")
  For Each $Element In $MyArray
    ? $Element
  Next
Endif


If $FailedAddPrinters ; or $FailedDelPrinters
  ? "Kontakt netværksadministratoren."
  ? "Tryk på en tast for at fortsætte..."
  Get $x
  ? ""
  ? ""
Endif

Exit


Du sætter blot NT1 = din server og retter printernavnene til funktionskaldene til AddPrinter().

Ja, jeg har nogenlunde den samme funktionalitet i et VBscript. Er der ingen mulighed for at tilføje printeren "statisk" til en maskine, således at printeren følger maskinen og ikke brugeren?