erstat emailadresser fra db

Hvis du henter sådan her
email = rs("mail")
Så får du det sådan her
link = "<a href=""mailto:" &email& """>Kontakt mig</a>"

Det er hvis du har feltet som mail direkte
Hvis du har en længere tekst kan du finde en løsning gemmen denne her
http://www.eksperten.dk/spm/614345

Forskellen er så blot at løsningen laver http:// ... det skal selvfølgelig rettes til mailto: :o)

<a href="mailto:Mail@udbyder.dk">Kontakt mig
</a>

psychedelic >> hvad skete der lige der ? ;o) LOL

hehe ja, men jeg glemte lige jeg var inde under ASP (:
kender ikke ret meget til Asp, men bare sig til, min fætter kender meget til asp (:

http://www.tek-tips.com/faqs.cfm?fid=4737

Der er et par fejl, i de er blevet rettet her:
<%
Function InsertHyperlinks(inText)
Dim objRegExp, strBuf
Dim objMatches, objMatch
Dim Value, ReplaceValue, iStart, iEnd

  strBuf = ""
  iStart = 1
  iEnd = 1
  Set objRegExp = New RegExp

  objRegExp.Pattern = "\b(www|http|\S+@)\S+\b"  ' Match URLs and emails
  objRegExp.IgnoreCase = True                  ' Set case insensitivity.
  objRegExp.Global = True                      ' Set global applicability.
  Set objMatches = objRegExp.Execute(inText)
  For Each objMatch in objMatches
    iEnd = objMatch.FirstIndex
    strBuf = strBuf & Mid(inText, iStart, iEnd-iStart+1)
    If InStr(1, objMatch.Value, "@") Then
      strBuf = strBuf & GetHref(objMatch.Value, "EMAIL", "_BLANK")
    Else
      strBuf = strBuf & GetHref(objMatch.Value, "WEB", "_BLANK")
    End If
    iStart = iEnd+objMatch.Length+1
  Next
  strBuf = strBuf & Mid(inText, iStart)
  InsertHyperlinks = strBuf
End Function


Function GetHref(url, urlType, Target)
Dim strBuf

  strBuf = "<a href="""
  If UCase(urlType) = "WEB" Then
    If LCase(Left(url, 3)) = "www" Then
      strBuf = "<a href=""http://" & url & """ Target=""" & Target & """>" & url & "</a>"
    Else
      strBuf = "<a href=""" & url & """ Target=""" & Target & """>" & url & "</a>"
    End If
  ElseIf UCase(urlType) = "EMAIL" Then
    strBuf = "<a href=""mailto:" & url & """ Target=""" & Target & """>" & url & "</a>"
  End If
 
  GetHref = strBuf

End Function


response.write InsertHyperlinks("hej med dig, håber det gå godt. MVH kenneth@dalbjerg.nu, se min hjemmeside http://www.dalbjerg.nu")
%>

svarer lige...

Tak, brugte Dalbjerg's version.