Eksporter til XML forts. fra spm 615166 BAK

jo, jeg skal nok vende tilbage, men ikke før mandag :-)

Helt fint! Jeg var ikke sikker på om vi havde talt forbi hinanden.

Så har jeg kigget lidt på det.
Har lagt et tyndt eksempel her:
http://www.tbdl.dk/excel/xmlver2.xls


Her er koden. Håber den er lidt selvforklarende :-)


Sub XMLNiveauTest()

Dim oXMLDOM As Object  'As DOMDocument40
Dim oProcessInfo As Object  'As IXMLDOMProcessingInstruction
Dim oNiveau1 As Object
Dim oNiveau2 As Object
Dim oNiveau3 As Object
Dim rngXML As Range
Dim rngCell As Range

  Set rngXML = Sheets("Ark3").Range("A2:A50")
  Set oXMLDOM = CreateObject("Microsoft.XMLDOM")
  Set oProcessInfo = oXMLDOM.createProcessingInstruction("xml", "version='1.0' encoding='UTF-8'")
  'opret hovedelementerne
  Set oXMLDOM.documentElement = oXMLDOM.createElement("Root")  'niveau1
  Set oNiveau2 = oXMLDOM.createElement("Product")    'niveau 2
  Set oNiveau3 = oXMLDOM.createElement("Type")      'niveau 3
  'Processing instructions
  oXMLDOM.insertBefore oProcessInfo, oXMLDOM.childNodes.Item(0)
  'opret underelementerne
  oNiveau2.appendChild oXMLDOM.createElement("Navn")

  oNiveau3.appendChild oXMLDOM.createElement("ID")
  oNiveau3.appendChild oXMLDOM.createElement("Orig")

  'kør igennem alle celler i rngXML
  For Each rngCell In rngXML
      'indsæt i elementet navn fra kolonne A
      oNiveau2.childNodes(0).Text = rngCell.Offset(, 0).Text
      'indsæt i elementet Type underelementerne ID og Orig fra kolonne B og C
      oNiveau3.childNodes(0).Text = rngCell.Offset(, 1).Text
      oNiveau3.childNodes(1).Text = rngCell.Offset(, 2).Text
      'sammenkobling af niveau 2 og 3
      'her "appendes" hele niveau3 til niveau2
      oNiveau2.appendChild oNiveau3
      'Klargør hele noden
      oXMLDOM.documentElement.appendChild oNiveau2.CloneNode(True)
  Next
  'lav fil
  oXMLDOM.Save (ThisWorkbook.Path & "\myXMLfile2.xml")
  'ryd op
  Set oProcessInfo = Nothing
  Set oXMLDOM = Nothing
  Set oNiveau1 = Nothing
  Set oNiveau2 = Nothing
  Set oNiveau3 = Nothing
  MsgBox "Færdig, filen ligger her : " & vbCrLf & ThisWorkbook.Path & "\myXMLfile2.xml", vbInformation
End Sub

skal lige siges at variablen oNiveau1 aldrig tages ibrug, så slet bare de par linier

Lige i øjet. Det var samme løsning jeg kom frem til i eftermiddags.

Rart at få bekræftet fremgangsmåden var rigtig.

Vil du lægge et svar og kan du fortælle mig om man kan tilføje formattering når man saver så linierne ikke skrives ud i et?

godt vi er enige :-)
Hvis du ser den gemte fil i notepad er der skrevet ud i et, men hvis du vælger at se filen i en browser er strukturen helt anderledes. Her kan du se hver linie og både kollapse emnerne og expande dem.
ex._

  <?xml version="1.0" encoding="UTF-8" ?>
- <Root>
- <Product>
  <Navn>Navn1</Navn>
- <Type>
  <ID>Id1</ID>
  <Orig>Origin1</Orig>
  </Type>
  </Product>
- <Product>
  <Navn>Navn2</Navn>
- <Type>
  <ID>Id2</ID>
  <Orig>Origin2</Orig>
  </Type>
  </Product>
- <Product>

Ja, men det var netop udseendet i f.x. notepad jeg var nysgerrig efter.

Men tak for indsatsen!