Cellereference i en makro

Her kommer den omtalte makro

Sub Color_graph()

Const DMin As Double = 10
Dim lCnt As Long
Dim rCell As Range
Dim YRange As Range
Dim MyChart As Chart
Dim vYRange
  If ActiveChart Is Nothing Then
      MsgBox ("Marker en graf, før du kører makroen")
      Exit Sub
  Else
    Set MyChart = ActiveChart
  End If
    vYRange = Split(MyChart.SeriesCollection(1).Formula, ",")
    Set YRange = Range(vYRange(2))
    lCnt = 0
    For Each rCell In YRange
        lCnt = lCnt + 1
        With MyChart.SeriesCollection(1).Points(lCnt).Interior
            If rCell.Value < DMin Then .ColorIndex = 3 Else .ColorIndex = 4
        End With
    Next
End Sub

Du kan ikke lade en const læse en værdi fra en celle.
Du kan sagtens gøre sådan her:

Dim DMin
DMin = Range("C5")

Dim DMin As ?

Får denne fejlmeddelelse,

Run-time error '1004'
Metod 'Range' of objekt_Global failed

Prøv lige med

DMin = Sheets("ark1").range("c5")

Og du kan dimm dmin til double,long , variant etc. (efter ønske og formål)

Subscript out of range

Nu virker det.
Jeg havde omdøbt ark1 til Data.

koden kom til at se sådan ud.

Sub Color_graph2()

Dim DMin As Double
DMin = Sheets("Data").Range("C5")
Dim lCnt As Long
Dim rCell As Range
Dim YRange As Range
Dim MyChart As Chart
Dim vYRange
  If ActiveChart Is Nothing Then
      MsgBox ("Marker en graf, før du kører makroen")
      Exit Sub
  Else
    Set MyChart = ActiveChart
  End If
    vYRange = Split(MyChart.SeriesCollection(1).Formula, ",")
    Set YRange = Range(vYRange(2))
    lCnt = 0
    For Each rCell In YRange
        lCnt = lCnt + 1
        With MyChart.SeriesCollection(1).Points(lCnt).Interior
            If rCell.Value < DMin Then .ColorIndex = 3 Else .ColorIndex = 4
        End With
    Next
End Sub

Tak for hjælpen.