Så skal du se mester (jeg kunne ikke dy mig :)). Jeg har flikket noget kode sammen (en hel asp-side så det kan testes uden videre), som jeg tror/håber møder dine behov (se nedenfor).
Jeg vil dig knytte et par kommentarer til din datastruktur sammenholdt med den måde du vedligeholder data på. Du har mulighed for at vedligeholde et dansk ord flere gange, men stadig kun et felt at gemme det i. Derfor har jeg lavet en lille javascript ting som opdaterer de andre danske ord som kommer fra samme række i tbl_danish, når cursoren forlader feltet med det danske ord. Det er for at holde konsistens i datagrundlaget. Ud over det har jeg lagt det hele i samme asp-fil, da du så vender tilbage til samme side når du klikker opdater (og kan i princippet fortsætte din redigering).
Umiddelbart vil jeg sige: prøv det og så kan du lige melde tilbage om der er nogle misforståelser i det jeg har lavet. I tilfælde af rettelser vil jeg tage udgangspunkt i det jeg poster her, med mindre der er tale om en total misforståelse :)
Here goes:
<%@ language="VBscript" %>
<%
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("/") & "\..\data\db1.mdb;Persist Security Info=False"
set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open strConn
if Request.Form("Opdater") <> "" then
dim strSQL
dim fld
dim danUpdated
danUpdated = ","
for each fld in Request.Form
' Kontroller om det er et dansk-ord felt
if lcase(left(fld,5)) = "dansk" then
' udtræk id fra navnet på feltet
danid = right(fld,len(fld)-6)
' Kontroller om ordet er blevet opdateret tidligere i dette postback
if instr(1,danUpdated, "," & danid & ",") = 0 then
' hvis ikke tidligere opdateret, så gemmes id på ordet, så det
' ikke bliver opdateret flere gange i dette postback
danUpdated = danUpdated & danid & ","
strSQL = "UPDATE tbl_danish SET "
strSQL = strSQL & " Dansk='" & Replace(Request.Form(fld)(1), "'", "''") &"' "
strSQL = strSQL & " WHERE id_dansk ="& danid
Conn.Execute(strSQL)
else
Response.Write("Been there! ("& fld &")<br>")
end if
end if
' Kontroller om det er et engelsk-ord felt
if lcase(left(fld,7)) = "engelsk" then
' Opdater det engelske ord og de tilhørende informationer
' til det engelske ord (klasse og orden)
engid = right(fld,len(fld)-8)
strSQL = "UPDATE tbl_english SET "
strSQL = strSQL & " Engelsk='" & Replace(Request.Form("Engelsk_" & engid), "'", "''") & "'"
strSQL = strSQL & ",Klasse='" & Replace(Request.Form("Klasse_" & engid), "'", "''") & "'"
strSQL = strSQL & ",Orden='" & Replace(Request.Form("Orden_" & engid), "'", "''") & "'"
strSQL = strSQL & " WHERE id_engelsk ="& engid
Conn.Execute(strSQL)
end if
next
end if
%>
<html>
<head>
<script type="text/javascript">
function syncWords(obj) {
// Opdater alle de andre kontroller med samme navn når en
// kontrols indhold ændrer sig. Dette er nødvendigt da
// ordet refererer til den samme række i tabellen i databasen.
var wordValue = obj.value;
var wordInputs = document.getElementsByName(obj.name);
if(wordInputs.length > 1) {
for(var i = 0; i < wordInputs.length; i++) {
wordInputs[i].value = wordValue;
}
}
}
</script>
</head>
<body>
<%
' SQL- sætning henter data
strSQL = "SELECT dan.id_dansk, dan.Dansk, eng.id_engelsk, eng.Engelsk, eng.Klasse, eng.Orden "
strSQL = strSQL & "FROM tbl_danish AS dan INNER JOIN tbl_english AS eng ON dan.id_dansk = eng.fr_dansk "
strSQL = strSQL & "ORDER BY LCase(dan.Dansk) "
Set rs = Conn.Execute(strSQL)
%>
<form action="<%=Request.ServerVariables("SCRIPT_NAME")%>" method="post">
<%
Do While Not rs.EOF
%>
<p>DK:<br>
<input type="text" value="<%=rs("Dansk")%>" name="Dansk_<%=rs("id_dansk")%>" onchange="syncWords(this)" size="60"></p>
<p>UK:<br>
<input type="text" value="<%=rs("Engelsk")%>" name="Engelsk_<%=rs("id_engelsk")%>" size="60"></p>
<p>Klasse:<br>
<input type="text" value="<%=rs("Klasse")%>" name="Klasse_<%=rs("id_engelsk")%>" size="60"></p>
<p>Orden:<br>
<input type="text" value="<%=rs("Orden")%>" name="Orden_<%=rs("id_engelsk")%>" size="60"></p>
<%
rs.MoveNext
Loop
%>
<p><input type="submit" value="Opdater" name="Opdater"></p>
</form>
<%
' Luk databaseforbindelse
Conn.Close
Set Conn = Nothing
%>
</body>
</html>
