Fra asp til javascript

Jeg har denne kode som er skrevet til asp - er der nogen som kan omdanne den så jeg i stedet kan køre den som javascript?

<%
Function GenererChecksumKode(varBetalingsId)

    ' Generer et betalingsid udfra retningslinjer angivet på side 4, afsnit 3 i
    ' "Fremstilling af indbetalingskort +71<" fra PBS
   
    Dim strBetalingsId
    Dim lngResult, lngFaktor, lngCiffer
    Dim i
   
    If IsNull(varBetalingsId) Then
        GenererChecksumKode = 0
    ElseIf (varBetalingsId = "") Then
        GenererChecksumKode = 0
    Else
        strBetalingsId = String(14 - Len(CStr(varBetalingsId)), "0") & varBetalingsId       
        ' gennemløb betalingsid forfra, og multiplicer hvert ciffer med hhv. 2 og 1
        lngFaktor = IIf(Len(strBetalingsId) Mod 2 = 0, 1, 2)
       
        For i = 1 To Len(strBetalingsId)
           
            lngCiffer = CLng(Mid(strBetalingsId, i, 1))
            lngResult = lngResult + Tvaersum(lngCiffer * lngFaktor)
            'response.write lngCiffer & ", " & lngFaktor & ", " & lngCiffer * lngFaktor & " (" & lngResult & ")"
       
            lngFaktor = IIf(lngFaktor = 2, 1, 2)  ' skiftevis 2 og 1
        Next
       
        If (lngResult Mod 10) = 0 Then
            GenererChecksumKode = strBetalingsId & "0"
        Else
            GenererChecksumKode = strBetalingsId & CStr(10 - (lngResult Mod 10))
        End If
           
    End If
   
End Function

Function Tvaersum(lng)

    ' Udregner tværsum for det givne tal
   
    Dim str
    Dim lngResult, i
   
    str = CStr(lng)
   
    For i = 1 To Len(str)
        lngResult = lngResult + CLng(Mid(str, i, 1))
    Next
   
    Tvaersum = lngResult
   
End Function

Function IIf(bResult, ReturnTrue, ReturnFalse)
    If bResult Then
        IIf = ReturnTrue
    Else
        IIf = ReturnFalse
    End If
End Function


'*********************************************************************************************

dim strOCR

strOCR = GenererChecksumKode(ordreid)

'*********************************************************************************************
%>