print til netværksprinter via Command prompt

du går ud i en dos prompt og skriver copy filnavn \\servernavn\printernavn

Virker ikke....

Printeren har indbygget netkort, så sider ikke på en server og er shared....

Der findes mange mange varianter, så jeg gav dig den nemme. som er afledt af
copy filnavn [\\computernavn\sharenavn\[enhed] [adgangskode] | *]]
som kan findes, hvis du i en DOS prompt skiver net use /?

du kan også skrive copy /? i en DOS prompt, men den er mere uoverskuelig.

Jeg tror du skal lege lidt med den første variant, og husk Rom blev ikke bygget på en dag.

Helt OK.

Jeg er dog temmelig meget hjemme i DOS/Windows, så har været alle kommandoer igennem som jeg kunne komme i tanke om.
Derfor synes jeg det var mærkeligt at jeg ikke kunne finde noget der virker, hvor det er muligt at printe til en netværksprinter.

Jeg har haft printeren koblet til en PC med parallel kabel, og så shared den der fra. Det virker helt som det skal.
Men kobler jeg den på netværket via det indbyggede netkort, og giver den en fast IP address, så er der ikke hul igennem.

Hvis du vil gøre det nemmere for dig selv kan du "hente printerport" som man kunne med Win98, det kræver dog at printeren er installeret (ikke fysisk) og delt på en server, så kan du bruge net use for eks.
net use lpt1: \\MS-2003\LaserJet. /Y

så kan du bare skrive copy tekstfil lpt1

Ja, det var også en muliged, men desværre kan denne løsning ikke bruges, da printeren SKAL forbindes via det indbyggede netkort.

En netprinter skal for at den skal kunne shares vel have en PC en Server eller noget at shares ud fra, eller har jeg misforstået noget. Min netværksprinter er forbundet med et netkabel og tilfældigvis installeret og sharet på en 2003 server.

Denne her er bare forbundet med en switch som resten af netværket.
I printeren's menu er den sat op med en fast IP addresse.

For at tilføje printeren i Windows, har jeg bare valgt "local printer" og "create new port".
Her har jeg så valgt TCP/IP, og indtastet printerens IP addresse. Det virker skam fint.

Hvor mange PC'er har du, hvor du skal kunne printe disse tekstfiler fra?

Det kan være alt mellem 2 og 50.....

Men faktisk har jeg fundet en løsning.
Jeg fandt en .bat fil på nettet som kunne printe til en netværksprinter.
Det eneste det kræver, er at printeren allerede er sat op i Windows, or markeret som standard.

@ECHO OFF
:: For Windows NT 4 or later only
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Localize variables
SETLOCAL
SET PrintCmd=
SET FileType=

:: Command line parsing
IF "%~1"==""  GOTO Syntax
IF "%~n1"=="" GOTO Syntax
IF "%~x1"=="" GOTO Syntax
SET File2Print=%~1
ECHO.%File2Print% ¦ FIND "?" >NUL
IF NOT ERRORLEVEL 1 GOTO Syntax
IF NOT EXIST "%File2Print%" GOTO Syntax

:: Strip quotes from TEMP variable
SET TEMP=%TEMP:"=%

:: Get the file association from the registry
FOR /F "tokens=3*" %%A IN ('REG.EXE QUERY "HKEY_CLASSES_ROOT\%~x1" /ve') DO SET FileType=%%B
SET Filetype=%FileType:"=%

:: Get the print command for this file type from the registry
FOR /F "tokens=3*" %%A IN ('REG.EXE QUERY "HKEY_CLASSES_ROOT\%FileType%\shell\print\command" /ve') DO SET PrintCmd=%%B
:: If no default was found, then the file type is probably unknown in Windows
IF NOT DEFINED PrintCmd GOTO NoAssoc
SET PrintCmd=%PrintCmd:\"="%
SET PrintCmd=%PrintCmd:""="%
SET PrintCmd=%PrintCmd:\\=\%
:: Next line enables long file names, added by Michael Lintner
SET PrintCmd=%PrintCmd:"%1"=%%1%

:: Actual print command has to be stored in a temporary batch file,
:: which is used as the batch language's "eval" substitute
> "%TEMP%.\~PrintAny.bat" ECHO START "Print" %PrintCmd%
CALL "%TEMP%.\~PrintAny.bat"

:: Cleanup
DEL "%TEMP%.\~PrintAny*.*"

:: Done
GOTO End

:NoAssoc
ECHO.
ECHO Sorry, this batch file works only for known file types with associated
ECHO print commands defined in the registry hive HKEY_CLASSES_ROOT.

:Syntax
ECHO.
ECHO PrintAny.bat,  Version 1.01 for Windows NT 4 / 2000
ECHO Prints any known file type from the command line
ECHO.
ECHO Usage:  PRINTANY  file_to_print
ECHO.
ECHO Where:  "file_to_print" is the name of the file to be printed.
ECHO.
ECHO Notes:  This batch file works only if the file type's print command
ECHO        is defined in the registry hive HKEY_CLASSES_ROOT.
ECHO        This batch file requires REG.EXE, which is native in Windows
ECHO        2000 and later, or part of the Windows NT 4 Resource Kit.
ECHO        Idea inspired by Eric Grux.
ECHO        Modification to enable long file names by Michael Lintner.
ECHO.

:End
IF "%OS%"=="Windows_NT" ENDLOCAL

Jeg har testet det, og det virker tilfredsstillende.
Men du får lidt for ulejligheden. :-)

Tak for det