Eksporter aktuel record til word i flette felter

Ingen der kender til dette fænomen?

Kan du ikke fjerne beskyttelsen, indsætte felterne og låse igen - alt sammen i VB?

umiddelbart nej, for felterne bliver ryddet, når dokumentet skifter status (låst/åbent)
Men jeg kan da prøve, ved du hvad kommandoen er til at låse doc i vb?

Det helt store "problem" er følgende, i mit word dok. er der en række afkrydsningsfelter og disse, kan man ikke "bare" klikke på for at markere/fjerne markering. Man skal enten dobb. klikke og skite og herefter klikke OK, eller højreklikke->egenskaber->skifte status.

Begge dele er i mine øjne noget juks. brugeren skal kunne oprette et brev på baggrund af record, klikke de relevante afkrydninsfelter og gemme brevet under kunden.

Jeg er ikke helt med. Fremgangsmåden må være:
1. Fra VBA kalder du en skabelon med bogmærker og afkrydsningsfelter osv.
2. Så hopper du til bogmærkerne og indsætter felterne fra posten
3. Derefter låser du dokumentet (kun den sektion, hvor er er afkrydsningsfelter)
Det giver dig et dokument med afkrydsningsfelter, du kan klikke helt normalt på.

... og skabelonen er selvfølgelig ikke låst. Det sker jo senere  ;o)

Så skidt da. Her er en grovskitse, der burde give dig en ide om fremgangsmåden:

1. Opret en Word skabelon med 3 sektioner
2. Indsæt bogmærket "Start" et eller andet sted i sektion 1
3. Indsæt nogle afkrydsningsfelter i sektion 2
4. Indsæt bogmærket "EtBogmærke" et eller andet sted i sektion 3
5. Gem skabelonen som "C:\Temp\EnSkabelon.dot"
6. Kør nedenstående kode fra Access VBA

Sub Kald_Word()
  Dim WordApp As Object

  If ActivWord Then
    Set WordApp = GetObject(, "Word.Application")
  Else
    Set WordApp = CreateObject("Word.Application")
  End If
 
  With WordApp
    .Visible = True
    .Activate
    .WindowState = 1
    ' Opret nyt dokument
    .Documents.Add Template:="C:\Temp\EnSkabelon.dot"
 
    ' Indsæt tekst
    .ActiveDocument.Bookmarks("EtBogmærke").Select
    .Selection.Find.ClearFormatting
    .Selection.TypeText "EnTekst"
 
    ' Beskyt dokument (lås sektion 2)
    .ActiveDocument.Sections(1).ProtectedForForms = False
    .ActiveDocument.Sections(2).ProtectedForForms = True
    .ActiveDocument.Sections(3).ProtectedForForms = False
    .ActiveDocument.Protect 2    ' 2=Udfyld formular tilstand
 
    ' Afslut
    .ActiveDocument.Bookmarks("Start").Select
    .Selection.Find.ClearFormatting
  End With
End Sub

Function ActivWord() As Boolean
  Dim WordApp As Object
  On Error Resume Next
  Set WordApp = GetObject(, "Word.Application")
  If Err <> 0 Then
    ActivWord = False
  Else
    ActivWord = True
  End If
  Err.Clear
End Function

fdata>> smid et svar og lad mig forgylde dig lidt ;-)

Det var lige præcis denne løsning, jeg håbede, ønskede!
Så er det nemlig dejligt, nemt for brugerne og selv rette småting, for mig at udvide osv osv.

Et svar

Takker for guld  ;o)