Ekspert udfodring?

Den er nem.

Denne makro er ikke testet, så det må du lige selv gøre.
Du skal kun have åbnet filen med de nye data.
Er der noget du ikke kan finde ud af, så skriv.

Public Sub Exp663895()
    Const sSalesFile As String = "C:\Temp\SalesView.xls" 'Skal ændres
    Const sSalesSheetName As String = "Sheet1" 'Skal ændres
    Dim wkbNew As Excel.Workbook
    Dim wkbSales As Excel.Workbook
    Dim wksImport As Excel.Worksheet
    Dim wksView As Excel.Worksheet
    Dim lRowFrom As Long
    Dim lRowTo As Long
    Dim bFound As Boolean

    On Error GoTo CleanUp
    Set wkbNew = ActiveWorkbook
    Set wksImport = wkbNew.ActiveSheet
    Set wksView = Application.Workbooks.Open(Filename:=sSalesFile)

    For lRowFrom = 1 To wksImport.UsedRange.Rows.Count
        bFound = False
       
        For lRowTo = 1 To wksView.UsedRange.Rows.Count

            If wksImport.Cells(lRowFrom, 1).Value = _
              wksView.Cells(lRowTo, 1).Value Then

                wksView.Cells(lRowTo, 1).End(xlToRight).Offset(0, 1).Value = _
                    wksImport.Cells(lRowFrom, 2).Value
                bFound = True
                Exit For

            End If

        Next lRowTo

        If Not bFound Then
            'Cellen bliver rød, hvis ikke den er overført til opsummeringsarket
            wksImport.Cells(lRowFrom, 1).Interior.ColorIndex = 3
        End If
    Next lRowFrom


CleanUp:
    Set wksImport = Nothing
    Set wksView = Nothing
    Set wkbNew = Nothing
    Set wkbSales = Nothing
End Sub

Makroen åbner filen salgsoversigt men overfører ikke tallene.Der kommer ingen fejlmeddelelse.
Muligvis skyldes fejlen det her:
I mit regneark "update" som jeg får hver måned er kundens nr og kundens navn i samme kolonne nemlig kolonne A, mens i mit ragneark salgsoversigt er kunde nr i kolonne A og kunde navn i kolonne B.

Ændre if-sætningen til:
If Val(wksImport.Cells(lRowFrom, 1).Value) = _

det skulle virke, hvis kundenr. står først.

Det er ikke hjulpet. Makroen åbner filen salgsoversigt men overfører ikke tallene.Der kommer ingen fejlmeddelelse.

Vil du sende mig filerne eller et uddrag af dem, så fixer vi lige det sidste. fvd@smartoffice.dk

Filerne er sendt.

Private Sub CommandButton1_Click()
'Public Sub Exp663895()
    Const sSalesFile As String = "d:\salgsoversigt.xls" 'Skal ændres
    Const sSalesSheetName As String = "Ark1" 'Skal ændres
    ' sCellToWriteIn - Skal ændres hver måned, så der skrives i den
    ' rigtige kolonne det er nødvendigt fordi kolonnen ikke kan findes
    ' automatisk, når ikke der er tal i alle celler.
    Const sCellToWriteIn As String = "Z1"
    Dim wkbNew As Excel.Workbook
    Dim wkbSales As Excel.Workbook
    Dim wksImport As Excel.Worksheet
    Dim wksView As Excel.Worksheet
    Dim lRowFrom As Long
    Dim lRowTo As Long
    Dim bFound As Boolean

    'On Error GoTo CleanUp
    Set wkbNew = ActiveWorkbook
    Set wksImport = wkbNew.ActiveSheet
    Set wkbSales = Application.Workbooks.Open(Filename:=sSalesFile)
    Set wksView = wkbSales.Worksheets(sSalesSheetName)

    ' 2-tallet her bestemmer hvilken række det første kundenr findes i (Update-filen)
    For lRowFrom = 2 To wksImport.UsedRange.Rows.Count
        bFound = False
       
        ' 3-tallet her bestemmer hvilken række det første kundenr findes i (Salgsview-filen)
        For lRowTo = 3 To wksView.UsedRange.Rows.Count

            If Val(wksImport.Cells(lRowFrom, 1).Value) = _
              wksView.Cells(lRowTo, 1).Value Then

                wksView.Cells(lRowTo, wksView.Range(sCellToWriteIn).Column).Value = _
                    wksImport.Cells(lRowFrom, 2).Value
                bFound = True
                Exit For

            End If

        Next lRowTo

        If Not bFound Then
            'Cellen bliver rød, hvis ikke den er overført til opsummeringsarket
            wksImport.Cells(lRowFrom, 1).Interior.ColorIndex = 3
        End If
    Next lRowFrom


CleanUp:
    Set wksImport = Nothing
    Set wksView = Nothing
    Set wkbNew = Nothing
    Set wkbSales = Nothing
'End Sub
End Sub

Den virker så længe det er en eksisterende kunde, men hvis der er en ny kunde oprettes ikke en ny linie i salgsoverigt filen med kundens navn og mængde. Kunden bliver bare markeret med rødt.

Nej, de nye kunder bliver RØDE i Update arket - dem må du oprette manuelt (læs at jeg ikke laver det for dig)

Ok, du får 100 point.