Sub main, byreftest, byvaltest

Sub main, har den formål at starte f.eks. i stedet for en form.

det kan man så evt. bruge til at vise en splash screens mens man loader nolge indstilinger, ofr at vise hovedvinduet.

hej thomaxz Tak for dit svar. Jeg synes ikke, at jeg får svar på det, som jeg spørger om, og så vidt jeg kan se, siger du ikke noget om byreftest byvaltest?
Kan du tydeliggøre det du skriver, for jeg er ikke blevet klogere.

så vidt jeg ved er forskellen at den ene kopiere variable over og ændre ikke den originale mens den anden sendere addressen til variable og bruger den.

jeg ved så ikke hvad det er hvad,og derfor jeg undlod at svare.

hej thomaxz Jeg har vist nu fundet ud af det med main, så det skal du nok få points for. Men det andet...
Næh, jeg forstår stadig ikke meningen, og derfor så jeg gerne et eksempel.
Jeg lader spørgsmålet stå åbent til i morgen. Måske kommer der en løsning.

Når jeg kan da prøve om jeg kan forklar det så du forstår det :D


Option Explicit

' ByRef: Kan ændre den variabel som er kommet ind i strPath (strTestPath)
Public Function SplitPath(strPath As String) As String
Dim intRev As Long
  ' Finder den sidste slash (\) i strPath og retuner position.
  intRev = InStrRev(strPath, "\")
  ' Hvis intRev er større end 0, så fortsættes..
  If intRev > 0 Then
    ' Retuner filnavnet tilbage til SplitPath.
    SplitPath = Right$(strPath, Len(strPath) - intRev)
    ' Setter strPath = biblioteks dir (ByRef)
    ' Det vil ændre den variabel som er kommet ind i strPath (strTestPath)
    strPath = Left$(strPath, intRev)
  End If ' end intRev
End Function

'ByVal: Her kan vi bruge strPath som en ny variabel, uden at det ændre noget ved (strTestPath)
Public Function ReplacePath1(ByVal strPath As String) As String
'Dim strTemp As String
  ' Fjrener mellemrum i bægge ender Trim$()
  strPath = Trim$(strPath)
  ' Erstatter "/" med "\"
  strPath = Replace(strPath, "/", "\")
  ' Erstatter "\\" med "\" og retuner det.
  ReplacePath1 = Replace(strPath, "\\", "\")
End Function

' ByRef: Her må vi lave en ny variabel (strTemp) for at den ikke ændre på strPath (strTestPath)
Public Function ReplacePath2(strPath As String) As String
Dim strTemp As String
  ' Kopier strPath til strTemp
  strTemp = strPath
  ' Fjrener mellemrum i bægge ender Trim$()
  strTemp = Trim$(strTemp)
  ' Erstatter "/" med "\"
  strTemp = Replace(strTemp, "/", "\")
  ' Erstatter "\\" med "\" og retuner det.
  ReplacePath2 = Replace(strTemp, "\\", "\")
End Function

Private Sub Form_Load()
Dim strTestPath As String
Dim strTestFile As String
Dim strTestReplace As String

  ' ByRef test
  strTestPath = "C:\bla\bla\bla\file.txt"
  MsgBox "(1) strTestPath = " & strTestPath

  strTestFile = SplitPath(strTestPath)

  MsgBox "(2) strTestPath = " & strTestPath
  MsgBox "(3) strTestFile = " & strTestFile


  ' ByVal test
  strTestPath = "C://bla//bla//bla/file.txt"
  MsgBox "(4) strTestPath = " & strTestPath

  strTestReplace = ReplacePath1(strTestPath)
  ' Eller ByRef
  ' strTestReplace = ReplacePath2(strTestPath)

  MsgBox "(5) strTestPath = " & strTestPath
  MsgBox "(6) strTestReplace = " & strTestReplace

End Sub

SJH Det må jeg studere nærmere, men jeg er sikker på, at dit svar er rigtigt, så jeg lukker for spørgsmålet nu. Mange tak for hjælpen.

thomaxz - jeg kunne ikke finde ud af at fordele, så der er points til dig her:
http://exp.dk/spm/670689

ok.