Request XML

Kilde: magik.dk

<%
Dim objXMLHTTP, objXMLDOM, objTitles, objURLs, i

'Opretter en instans af Microsoft.XMLHTTP,
'så det er muligt at få fat på dokumentet
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")

'Opretter en instans af Microsofts XML-parser, XMLDOM
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")

'Opretter forbindelse til xml-dokumentet
Call objXMLHTTP.Open("GET", "http://www.magik.dk/da/links/xml/", False)

objXMLHTTP.Send

'Lægger indholdet af dokumentet over i vores XML-parser objekt
Set objXMLDOM = objXMLHTTP.ResponseXML

'Henter indholdet af alle tags med navnet 'titel'
Set objTitles = objXMLDOM.getElementsByTagName("titel")

'Henter indholdet af alle tags med navnet 'url'
Set objURLs = objXMLDOM.getElementsByTagName("url")

Response.Write("<table width=""100%""
    cellspacing=""5"" cellpadding=""5"">")

'Løber igennem alle tags, og udskriver dem i en tabel
For i = 0 To objTitles.length - 1

  Response.Write("<tr>")
  Response.Write("<td width='200'>")
  Response.Write("<a href='" & objURLs(i).text & "' target='_blank'>")
  Response.Write(objTitles(i).text & "</a></td>")
  Response.Write("</tr>")

Next

Response.Write("</table>")

Set objXMLHTTP = Nothing
Set objXMLDOM = Nothing
%>

Hejsa tak for det, men det filen fra Nationalbanken jeg gerne vil have lavet.

Her et eksemple som ligger data ind i en tabel:

<%
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Set objXMLDOM = Server.CreateObject("Microsoft.XMLDOM")
Call objXMLHTTP.Open("GET", "http://www.nationalbanken.dk/dndk/valuta.nsf/valuta.xml", False)
objXMLHTTP.Send
Set objXMLDOM = objXMLHTTP.ResponseXML

If objXMLDOM.parseError.errorcode = 0 Then
  'Udskriver datoen for kurserne i filen
  set datoen = objXMLDOM.getElementsByTagName("dailyrates")
  Response.Write "Dato : " & datoen(0).getAttribute("id")
  Response.Write "<br>"

  'Udskriver valuta data her
  set n=objXMLDOM.getElementsByTagName("currency")
  Response.Write "<table>"
  Response.Write "<tr><td>Code</td><td>Beskrivelse</td><td>Rate</td></tr>"
  for each node in n
    Response.Write "<tr>" 
    Response.Write "<td>" & node.getAttribute("code") & "</td>"
    Response.Write "<td>" & node.getAttribute("desc") & "</td>"
    Response.Write "<td>" & node.getAttribute("rate") & "</td>"
    Response.Write "</tr>"
  next
  Response.Write "</table>"
Else
  Response.Write ("There was an error")
End If
Set objXMLHTTP = Nothing
Set objXMLDOM = Nothing
%>

Kanon, det virker jo. Tusind tak