VBA - Import til Array til combobox

Navngiv dit data område.

Stil dig i celle a1 - tryk ctrl+shift+pil ned (markére dine netop importerede data).
Lige over kolonne A - står teksten A1, markér denne teskt og kald den f.eks. "Data" (uden gåseøjne) Enter.
Du har nu givet din import, navnet data, dette kan du referere til i din combobox


Indsæt nedenstående (dobbelt klik på din userform, ikke din combobox!)
Så vil din combobox, når din userform vises, tage værdierne i det navngivne område "Data"

    Private Sub UserForm_Activate()
    ComboBox1.RowSource = "Data"
    End Sub

Combobox1 skal selvfølgelig ændres hvis du har givet den et andet navn.


Det kører ikke helt automatisk, men så har du lidt at starte på....

Ok, jeg har måske formuleret mig dårligt.

Jeg ønsker ikke at importerer data til et område i Excel. Jeg ønsker direkte import til min combo.

Det andet er ikke noget problem.

Nå - lukketid!

Svaret blev at jeg lavede en import vha ADO - og gjorde det i en funktion (public function) som jeg brugte i min combobox... altså sådan her:

Public Function NameImport() As String()
'Returnerer data i array

  Dim rst As ADODB.Recordset
  Dim con As ADODB.Connection
  Dim com As ADODB.Command
  Dim strName() As String
  Dim i As Integer

  'Open connection
  Set con = New ADODB.Connection
  con.ConnectionString = "DSN=min_bruger_dsn;USER=xxx;PWD="
  con.Provider = "msdasql"
  con.Open

  'Create and manipulate command object
  Set com = New ADODB.Command
  com.ActiveConnection = con
  com.CommandText = "SELECT Name FROM Company"

  'Create and populate the recordset
  Set rst = New ADODB.Recordset
  rst.Open com, , adOpenKeyset

  'Walk the recordset
  With rst
    .MoveFirst
    i = 0
    Do While Not .EOF
          ReDim Preserve strName(i)
          strName(i) = !Name
          i = i + 1
        .MoveNext
    Loop
  End With

  'Clean up
  con.Close
 
  NameImport = strName
End Function

I min formular hvor jeg har jeg denne her:

Private Sub UserForm_Initialize()

ComboBox1.List = NameImport

End Sub