Find x antal højeste og beregn middel

Som eks. viser er det middel af alle 6 resultater. (=MIDDEL(B2:B30))

hej backside

=MIDDEL(A5:A8)

mvh

mvhansen

du vælger de 5

ok det er ikke lige det du søger

Ikke helt nej.
Den skal selv finde de 5 højeste.
Har rodet rundt længe nu, måtte ha´ lidt hjælp udefra.  ;)

prøv
=MIDDEL(F10:F15;1;2;3;4;5)

jeg var hvis for hurtig

et skud

=SUMPRODUKT((PLADS(B2:B30;B2:B30)<6)*(B2:B30))/5

=(STØRSTE(B3:C9;1)+STØRSTE(B3:C9;2)+STØRSTE(B3:C9;3)+STØRSTE(B3:C9;4)+STØRSTE(B3:C9;5))/5

bedste bud lige nu, ved ikke af om der findes en funktion til det

da der kan være flere der er lige store, er vi nød til at tælle dem, for at få gennemsnit.

prøv denne

=SUMPRODUKT((PLADS(B2:B30;B2:B30)<6)*(B2:B30))/SUMPRODUKT((PLADS(B2:B30;B2:B30)<6) * (PLADS(B2:B30;B2:B30)<6))

Kan ikke lige få det til at funke.

kabbaks er vist mere elegant

de virker nu ellers begge 2

Ok jeg kan se fejlen, der skal være værdier i cellerne, for at plads virker

Jeg kan kun få det til at virke hvis jeg rettet til de celler der er noget i.

Sorry, fik ikke opdateret.
Men ja, netop der problemet ligger.

Indsæt denne her som array-formel

=MIDDEL(STØRSTE(B2:B30;{1;2;3;4;5}))

Det bliver til en array-formel, når du afslutter indtastningen med ctrl-shift-enter istedet for bare enter. (Formlen får tuborg-klammer omkring {})

Sorry, den behøver ikke engang være array-formel. Bare indtast som normalt

jeg bukker for mesteren ;-))

Sådan der, der var den jo.
Hvis du vidste hvor meget tid jeg har brugt på det.  LOL

Men hvad nu hvis der er en der kun har 4 resultater?
Sæsonen starter jo med at alle har 0.
Kan man mon finde en løsning på det, eller er vi på overdrevet?

så bliver den jo nok en anelse mere avanceret

=HVIS(TÆL(B2:B30)>4;MIDDEL(STØRSTE(B2:B30;{1;2;3;4;5}));SUMPRODUKT(STØRSTE(B2:B30;RÆKKE(INDIREKTE("1:"&TÆL(B2:B30)))))/TÆL(B2:B30))

kabbak->buk nu ikke for dybt, det kan sagtens blive min tur snart :-)

Den der æder jeg sku, det er jo topklasse. :-)
Takker alle for hjælpen. Svar tak.

ok :-)

alternativt : jeg har døbt dataområde A2:B9 som 'y' - hos dig blir det nok B2:B30
Døb en celle hvor du har antal største som 'x' skal være tal mellem 2 og 6
Følgende formel beregner så middelværdi af de x største værdier i dataområde y
=HVIS(TÆL(y)>=x;HVIS(x=2;MIDDEL(STØRSTE(y;{1;2}));HVIS(x=3;MIDDEL(STØRSTE(y;{1;2;3}));HVIS(x=4;MIDDEL(STØRSTE(y;{1;2;3;4}));HVIS(x=5;MIDDEL(STØRSTE(y;{1;2;3;4;5}));HVIS(x=6;MIDDEL(STØRSTE(y;{1;2;3;4;5;6})))))));MIDDEL(y))

med denne formel, har du så mulighed for at ændre x værdi uden at skulle ændre i formel, samt den virker på en til flere kolonner,

Hmm, den fattede jeg ikke meget af.  :)
Men den skal da prøves af, jeg takker for forslaget.

husk strækøvelser :-)

har væddet en sofavand med min kolega om hvem der kommer med den korteste løsning

mit korteste bud på backsides oprindelige spm.
=HVIS(TÆL(B2:B30)>4;MIDDEL(STØRSTE(B2:B30;{1;2;3;4;5}));MIDDEL(B2:B30))

mit korteste bud på exelents udfordring
=HVIS(TÆL(y)>x;MIDDEL(STØRSTE(y;RÆKKE(INDIREKTE("1:" & x))));MIDDEL(y))
formlen indtastes som array-formel dvs. at indtastning afsluttes med ctrl-shift-enter istedet for bare enter, således at formlen automatisk får tuborg-klammer omkring sig {}.
i Celle X kan man skrive et hvilket som helst tal (næsten) og er således ikke begrænset til 6

oh my, den er der vist ingen der slår bak :-) well done
vi kommer nok til at sende en sofavand til Mr. Excel

Når jeg tænker på hvor mange øl jeg drak igår, lyder sofavand rigtigt fornuftig idag :-)

lol

Uha, man bliver helt rundtosset.
Og endnu en gang tak for ihærdigheden.  ;)

Tjaa bak !!. så er det din tur :-)

{=MIDDEL(STØRSTE(A2:B9;RÆKKE(INDIREKTE("1:"&D2))))}