SessionID pr. åben side

Den eneste anden metode jeg kan komme på (udover ?kunde=1234) er at bruge forskellige browsers. SessionID'et bliver faktisk styret af cookies, og da browserne har deres cookies forskellige steder, får de også et forskellig id.

Bruger det selv når jeg er logget ind som admin i et system, og jeg har brug for at se hvordan det ser ud hos brugeren. Så har jeg både en FF og IE igang, og en sjælden gang også OP.

Ellers skal du hashe kunde ID'et. Jeg arbejdede med det tidligere i dette ?:
http://www.eksperten.dk/spm/695272

min baggrund for ikke at vil bruge Request metoden er at jeg bruger den samme kode til at vise kunderne, når de bruger webshoppen, men når en medarbejder fra ordremodtagelsen logger på skal han/hun selv kunne vælge hvilken kunde han/hun er logget på som.
Så for ikke at skulle lave 2 programmer der næsten er ens ønsker jeg at fiden en metode så jeg kan bruge "noget" der ligner SessionID/cookies og dermed bruge samme koden lige meget om det er en kunne eller ordre modtagelsen der anvender programmet.
men ok hvis der ikke er andre der har forslag er der jo nok ingen vej uden om at anvende Request

Så sørg for at bruge den hash kode fra det ? jeg linkede til. På den måde kan dit system ikke hackes selv om kunde ID'et står i url'en. Det kommer nemlig til at stå som noget i denne stil:

dinSide.asp?kundeID=jh34jh43jhgv4gvv34hgvh34hgchg34

Bruger selv den kode nu, så jeg har det liggende i funktioner, som er lige til at bruge. Dem kan du lige så godt få.

2 sek...

<!--#include file="system/md5.asp"-->
<%

Function secureID(fID)
dim fTmp, fSecurityTekstString
    fSecurityTekstString = securityTekstString
    if fSecurityTekstString = "" then fSecurityTekstString = "Skriv din egen tekst her"
    fSecurityTekstString = fSecurityTekstString & date()
    fTmp = md5(fSecurityTekstString & fID)
    fTmp = left(fTmp, 10) & fID & mid(fTmp,11)
    secureID = fTmp
end Function

Function tjeckSecureID(fKode)
dim fTmp, fRetur, fHash, fID, fSecurityTekstString
    fSecurityTekstString = securityTekstString
    if fSecurityTekstString = "" then fSecurityTekstString = "Skriv din egen tekst her"
    fSecurityTekstString = fSecurityTekstString & date()
    fTmp = fKode
    if len(fTmp) <= 32 then
        fRetur = false
    else
        fHash = left(fKode,10) & mid(fKode,11+len(fKode)-32)
        fID = mid(fKode,11, len(fKode)-32)
        if md5(fSecurityTekstString & fID) = fHash then
            fRetur = true
        else
            fRetur = false
        end if
    end if
    tjeckSecureID = fRetur
end Function

Function getSecureID(fKode)
    if tjeckSecureID(fKode) then
        getSecureID = mid(fKode,11, len(fKode)-32)
    else
        Response.write "Forkert ID."
        response.end
    end if
end function
%>

Du skal have hentet md5.asp filen fra dette link:
http://www.asp-faq.dk/article/?id=52

Du bruger så disse koder i dine ASP filer:

kundeID = getSecureID(request.querystring("kundeID"))

<a href="enSide.asp?kundeID=<%= secureID(kundeID) %>">klik</a>

Hej igen jeg beklager ventetiden.

ja ok hvis jeg nu skal bruge Request så er denne måde da langt at foretrække

jeg siger tak for hjælpen

no prob
.o) <-- One Eyed Jack