Fjern alle HTML tags fra en tekst

Jeg ved at Eagleeye har lavet et script der gør netop hvad du søger. Prøv at søg i ASP-sektionen.

Jeg kigger selv efter den også

I min søgen fandt jeg denne. Jeg mindes at eagleeyes er bedre. (Denne har jeg ikk selv testet, da jeg ikk har mulighed for den lige pt)

<%
Function RemoveHTML(strContent)
  Do
    pos = 1
    tmpBegin = InStr(pos,strContent,"<")
    If tmpBegin > 0 Then
      pos = tmpBegin
      If LCase(mid(strContent,tmpBegin,7)) = "<script" Then
        ' Her fjernes script kode
        tmpEnd = Instr(tmpBegin,LCase(strContent),"</script>")
        strContent = Left(strContent,tmpBegin-1) & Right(strContent,Len(strContent)-tmpEnd-8)
      ElseIf LCase(mid(strContent,tmpBegin,2)) = Chr(60) & "%" Then
        ' Her fjernes ASP kode
        tmpEnd = Instr(tmpBegin,LCase(strContent),"%" & Chr(62))
        strContent = Left(strContent,tmpBegin-1) & Right(strContent,Len(strContent)-tmpEnd-3)
      Else
        ' Her fjernes HTML kode
        tmpEnd = InStr(pos,strContent,">")
        If tmpEnd > 0 Then
          strContent = Left(strContent,tmpBegin-1) & Right(strContent,Len(strContent)-tmpEnd)
        Else
          strContent = Left(strContent,tmpBegin-1)
          Exit Do
        End If
      End If
    Else
      Exit Do
    End If
  Loop
  RemoveHTML = strContent
End Function

tmpContent = Trim(Request.Form("HTML"))
If Len(tmpContent) > 0 Then
  Response.Write Replace(RemoveHTML(tmpContent), vbCrLf, "<br>")
  Response.End
End If
%>

Du kan også kigge lidt på denne:

<%
'[ClearHTMLTags]
   
'Coded by Jóhann Haukur Gunnarsson
'joi@innn.is
   
'  Purpose: This function clears all HTML tags from a
'          string using Regular Expressions.
'  Inputs: strHTML;
'            A string to be cleared of HTML TAGS
'    intWorkFlow;
'            An integer that if equals to 0 runs only the RegExp filter
'              .. 1 runs only the HTML source render filter
'              .. 2 runs both the RegExp and the HTML source render
'              .. >2 defaults to 0
'  Returns: A string that has been filtered by the function
   
function ClearHTMLTags(strHTML, intWorkFlow)
  'Variables used in the function
       
  dim regEx, strTagLess
       
  '---------------------------------------
  strTagless = strHTML
  'Move the string into a private variable
  'within the function
  '---------------------------------------

  'regEx initialization
  '---------------------------------------
  set regEx = New RegExp
  'Creates a regexp object       
  regEx.IgnoreCase = True
  'Don't give frat about case sensitivity
  regEx.Global = True
  'Global applicability
  '---------------------------------------

  'Phase I
  '    "bye bye html tags"
  if intWorkFlow <> 1 then
    '---------------------------------------
    regEx.Pattern = "<[^>]*>"
    'this pattern mathces any html tag
    strTagLess = regEx.Replace(strTagLess, "")
    'all html tags are stripped
    '---------------------------------------
  end if
       
  'Phase II
  '    "bye bye rouge leftovers"
  '    "or, I want to render the source"
  '    "as html."

  '---------------------------------------
  'We *might* still have rouge < and >
  'let's be positive that those that remain
  'are changed into html characters
  '---------------------------------------   

  if intWorkFlow > 0 and intWorkFlow < 3 then
    regEx.Pattern = "[<]"
    'matches a single <
    strTagLess = regEx.Replace(strTagLess, "<")

    regEx.Pattern = "[>]"
    'matches a single >
    strTagLess = regEx.Replace(strTagLess, ">")
    '---------------------------------------
  end if
       
  'Clean up
  '---------------------------------------
  set regEx = nothing
  'Destroys the regExp object
  '---------------------------------------   
       
  '---------------------------------------
  ClearHTMLTags = strTagLess
  'The results are passed back
  '---------------------------------------
end function
%>

Kanon . jeg havde ellers søgt, men uden held. Nu fandt jeg
http://www.eksperten.dk/spm/302158

der er en lille fix funkion der gør det jeg vil.

Svar bitte :-)

Kunne du bruge noget af det? Og har du fået du det til at virke?

Jeg I http://www.eksperten.dk/spm/302158 er der et link til Eagleeye's funktioner - de er ret gode :-)

Jamen så siger jeg mange tak for pointene.

Super at det virker :)