se log mappe igennem og vælg nyeste

Hedder alle filer "MDaemon-" til start eller er der forskellige navne??

alle filer hedder MDaemon-"dato"-Routing.log

som default hvor "20060706" er det eneste der ændre sig.

Med denne kode bliver filerne sorteret efter navnet. Vi er nemlig så heldige at din datoangivelse kan bruges i en text sortering:

dim FSO, folder, files, file, RS
Set FSO = CreateObject("Scripting.FileSystemObject")
Set folder = FSO.GetFolder(server.mapPath("."))
Set RS = Server.CreateObject("ADODB.Recordset")

RS.Fields.Append "Filnavn", 200, 20
RS.Open

For Each file in folder.Files
    RS.Addnew
    RS("Filnavn") = file.Name
    RS.Update
Next

RS.Sort = "Filnavn DESC"
RS.MoveFirst
while Not RS.EOF
  Response.Write RS("filnavn") & "<br>"
  RS.MoveNext
wend
RS.Close
Set RS =nothing
Set FSO =nothing

Dette kan du så bruge da du ved at den nyeste fil ligger først:

...
RS.Sort = "Filnavn DESC"
RS.MoveFirst
Set File = FSO.OpenTextFile(server.mappath(RS("filnavn")), 1, Create)
If not File.AtEndOfStream Then
  Do While not File.AtendOfStream
    newline = File.ReadLine
    response.write newLine &"<br>"
  loop
end if

Samme metode kan bruges til at sortere linjerne fra filen, hvis du vil have dem i omvent rækkefølge.

Du kan læse mere om sortering af filer via et recordset her:
http://www.roubaixinteractive.com/PlayGround/FSO/Sort_Folder_Contents.asp

Læg mærke til at de her også gemme filens "dateCreated" så du kan faktisk sortere efter det felt i stedet hvis det skal være.

Du skal evt have udbygget files loopet lidt, så den kun tager dine MDaemon filer, hvis du har andre filer til at ligger i samme mappe:

For Each file in folder.Files
  if left(file.Name, 7) = "MDaemon" then
    RS.Addnew
    RS("Filnavn") = file.Name
    RS.Update
  end if
Next

Dine filnavne er længere end 20 tegn så vi skal lige have udvidet feltet til mere end 20 tegn:

RS.Fields.Append "Filnavn", 200, 50

<% dim FSO, folder, files, file, RS
Set FSO = CreateObject("Scripting.FileSystemObject")
Set folder = FSO.GetFolder(server.mapPath("/log"))
Set RS = Server.CreateObject("ADODB.Recordset")

RS.Fields.Append "Filnavn", 200, 20
RS.Open

For Each file in folder.Files
  if left(file.Name, 7) = "MDaemon" then
    RS.Addnew
    RS("Filnavn") = file.Name
    RS.Update
  end if
Next

RS.Sort = "Filnavn DESC"
RS.MoveFirst
while Not RS.EOF
  Response.Write RS("filnavn") & "<br>"
  RS.MoveNext
wend
RS.Close
Set RS =nothing
Set FSO =nothing

RS.Sort = "Filnavn DESC"
RS.MoveFirst
Set File = FSO.OpenTextFile(server.mappath(RS("filnavn")), 1, Create)
If not File.AtEndOfStream Then
  Do While not File.AtendOfStream
    newline = File.ReadLine
    response.write newLine &"<br>"
  loop
end if

%>

der får jeg bare:

Microsoft Cursor Engine error '80040e21'

Multiple-step operation generated errors. Check each status value.

/file.asp, line 12

linie 12 er:

RS("Filnavn") = file.Name

hov havde lige overset din over 20 char fejl...

efter jeg har rettet det får jeg:

MDaemon-20060706-Routing.log

Microsoft VBScript runtime error '800a01a8'

Object required

/file.asp, line 27

Hvad er linje 27??

RS.Sort = "Filnavn DESC" er linie 27

Det er fordi du lukker RS i linjerne før, og det første loop behøver vi ikke længere:

Set FSO = CreateObject("Scripting.FileSystemObject")
Set folder = FSO.GetFolder(server.mapPath("/log"))
Set RS = Server.CreateObject("ADODB.Recordset")
RS.Fields.Append "Filnavn", 200, 50
RS.Open

For Each file in folder.Files
  if left(file.Name, 7) = "MDaemon" then
    RS.Addnew
    RS("Filnavn") = file.Name
    RS.Update
  end if
Next

RS.Sort = "Filnavn DESC"
RS.MoveFirst
Set File = FSO.OpenTextFile(server.mappath(RS("filnavn")), 1, Create)
If not File.AtEndOfStream Then
  Do While not File.AtendOfStream
    newline = File.ReadLine
    response.write newLine &"<br>"
  loop
end if
RS.Close
Set RS =nothing
Set FSO =nothing

ok mange tka nu virker det.. en sidste ting dog, er det muligt at læse det modsat?

f.eks hvis txt filen så sådan her ud:
1
2
3
4
5

på hver sin linie så vil den vise med scriptet på skærmen

5
4
3
2
1

`?

samt det ser heller ikke ud til det er muligt at læse dem fra en anden mappe ved at ændre

Set folder = FSO.GetFolder(server.mapPath("."))

til

Set folder = FSO.GetFolder(server.mapPath("/log"))

f.eks?

Du skulle kunne læse fra en anden mappe, men når du starter med / går den til roden af dit webhotel, og finder log mappen. Du er måske i denne fil:
c:/interpub/wwwRoot/enMappe/minfil.asp

server.mapPath(".") returnere c:/interpub/wwwRoot/enMappe/
server.mapPath("/") returnere c:/interpub/wwwRoot/
server.mapPath("log") returnere c:/interpub/wwwRoot/enMappe/log
server.mapPath("/log") returnere c:/interpub/wwwRoot/log

Man kan mig bekendt ikke læse en fil baglæns. Men du kan bruge samme metode som med filerne. Vender tilbage med et eks lige om lidt.
...LOADING...
...LOADING...

he he

...DONE...

RS.Sort = "Filnavn DESC"
RS.MoveFirst
Set File = FSO.OpenTextFile(server.mappath(RS("filnavn")), 1, Create)
Set RS1 = Server.CreateObject("ADODB.Recordset")
RS1.Fields.Append "sort", 3
RS1.Fields.Append "Tekst", 200, 100
RS1.Open
counter = 0
If not File.AtEndOfStream Then
  Do While not File.AtendOfStream
    newline = File.ReadLine
    RS1.Addnew
    RS1("sort") = counter
    RS1("Tekst") = newLine
    RS1.Update
    counter = counter + 1
  loop
end if
RS1.Sort = "sort DESC"
RS1.MoveFirst
while not RS1.eof then
  Response.write RS1("Tekst") & "<br>"
  RS1.MoveNext
wend

Og har du ændret mappen skal du også gøre det i OpenTextFile
Set File = FSO.OpenTextFile(server.mappath("/log/"&RS("filnavn")), 1, Create)

Evt lave en Path variabel i starten også bruge den, så du nemt kan ændre mappen til en anden på et senere tidspunkt:
Path = server.mappath("/log")
Set folder = FSO.GetFolder(Path)
Set File = FSO.OpenTextFile(Path &"/"RS("filnavn")), 1, Create)

ok jeg får dog følgende fejl nu:

Microsoft VBScript compilation error '800a0400'

Expected statement

/file.asp, line 36

while not RS1.eof then
------------------^


min kode er:

<%Set FSO = CreateObject("Scripting.FileSystemObject")
Set folder = FSO.GetFolder(server.mapPath("log2"))

Set RS = Server.CreateObject("ADODB.Recordset")
RS.Fields.Append "Filnavn", 200, 50
RS.Open

For Each file in folder.Files
  if left(file.Name, 7) = "MDaemon" then
    RS.Addnew
    RS("Filnavn") = file.Name
    RS.Update
  end if
Next

RS.Sort = "Filnavn DESC"
RS.MoveFirst
Set File = FSO.OpenTextFile(server.mappath("/log2/"&RS("filnavn")), 1, Create)
Set RS1 = Server.CreateObject("ADODB.Recordset")
RS1.Fields.Append "sort", 3
RS1.Fields.Append "Tekst", 200, 100
RS1.Open
counter = 0
If not File.AtEndOfStream Then
  Do While not File.AtendOfStream
    newline = File.ReadLine
    RS1.Addnew
    RS1("sort") = counter
    RS1("Tekst") = newLine
    RS1.Update
    counter = counter + 1
  loop
end if
RS1.Sort = "sort DESC"
RS1.MoveFirst
while not RS1.eof then
  Response.write RS1("Tekst") & "<br>"
  RS1.MoveNext
wend %>

og linie 36 er:

while not RS1.eof then

min fejl. Der skal ikke "then" på en while:

while not RS1.eof

så får jeg:

Microsoft Cursor Engine error '80040e21'

Multiple-step operation generated errors. Check each status value.

/file.asp, line 29

linie 29 eR:

    RS1("Tekst") = newLine

Hvor lange er hver linje i log filen??
Det lader til at de er over 100 tegn lange, så du skal have sat feltstørrelsen op så den kan tage dem:

RS1.Fields.Append "Tekst", 200, xxx

ok satte den til 400 det så ud til at virke, hva bestemmer 200 ?

Samt der er lige et sidste problem før det virker.

der er andre filer i samme mappe der hedder f.eks

MDaemon-20060706-System.log
MDaemon-20060706-Statistics.log
MDaemon-20060706-SMTP-(in).log
MDaemon-20060706-Routing.log
MDaemon-20060706-RAW.log

osv problemet er den ser ud til bare at tage MDaemon-20060706-System.log og ik MDaemon-20060706-Routing.log er det muligt at ændre den lille del?

1:
Datatypen. De 3 mest brugte er:
200 = VarChar
7 = Date
3 = Int

2:
if left(file.Name, 7) = "MDaemon" and inStr(file.Name, "Routing") then

mange tak! smid så et svar :D

Angående 1. Så kan du se at "sort" er sat til at være et tal:
RS1.Fields.Append "sort", 3

.o) <-- One Eyed Jack

ok tak for forklaringen også! har bestemt hjulpent med forstårelsen af det her :)