kryptere url

Havde tidligere gang i en kode som gør det her:
http://www.eksperten.dk/spm/695272

Bruger den selv til at hashe nogle ID'er.

Du kan lige så godt få hele min kode (redigeret):

<!--#include file="system/md5.asp"-->
Function secureID(fID)
dim fTmp, fSecurityTekstString
  fSecurityTekstString = "HemligText"
  fSecurityTekstString = fSecurityTekstString & date()
  fTmp = md5(fSecurityTekstString & fID)
  fTmp = left(fTmp, 10) & fID & mid(fTmp,11)
  secureID = fTmp
end Function

Function tjeckSecureID(fKode)
dim fTmp, fRetur, fHash, fID, fSecurityTekstString
  fSecurityTekstString = "HemligText"
  fSecurityTekstString = fSecurityTekstString & date()
  fTmp = fKode
  if len(fTmp) <= 32 then
    fRetur = false
  else
    fHash = left(fKode,10) & mid(fKode,11+len(fKode)-32)
    fID = mid(fKode,11, len(fKode)-32)
    if md5(fSecurityTekstString & fID) = fHash then
        fRetur = true
    else
      fRetur = false
    end if
  end if
  tjeckSecureID = fRetur
end Function

Function getSecureID(fKode)
  if tjeckSecureID(fKode) then
    getSecureID = mid(fKode,11, len(fKode)-32)
  else
    Response.write "Forkert ID."
    response.end
  end if
end function

Jeg bruger md5 filen, som kan hentes her:
http://www.asp-faq.dk/article/?id=52

Du skal så overveje at placere ID'et et andet sted end plads 10, som vi gjorde i eksemplet (har selv flyttet den), samt finde på en anden "HemligText"

Du flytter ID'et ved at ændre alle 10 og 11 i funktionerne til f.eks 14 og 15.

ok kigger lige på det derhjemme, tak for det,,, giver dig svar  senere