Logning af åbning af excel fil der ligger på MS SBServer

Skal loggen være i selve filen eller en anden fil fx en testfil eller anden excel-mappe ?

Hej.
Loggen må meget gerne være en .txt fil

Her er et bud...
Koden indsættes i modulet ThisWorkBook
(Virker s'føli kun hvis makroer er enabled)
Du ændrer selv Folder og filnavn

Private Sub Workbook_Open()
    Const LogFile As String = "XLLog.txt"
    Const LogFolder As String = "E:\Logfolder3"
    Const ForAppend As Long = 8
    Dim FSO As Object
    Dim f As Object
    Dim MyStream As Object
    'opret et nyt FileSystemObject
    Set FSO = CreateObject("Scripting.filesystemobject")
   
    'hvis LogFolderen ikke eksisterer så opret den
    If Not FSO.folderexists(LogFolder) Then
        FSO.CreateFolder (LogFolder)
    End If
    'hvis LogFilen ikke eksisterer, så opret den
    If Not FSO.FileExists(LogFolder & "\" & LogFile) Then
        FSO.CreateTextFile (LogFolder & "\" & LogFile)
    End If
    'klargør filen
    Set f = FSO.GetFile(LogFolder & "\" & LogFile)
    Set MyStream = f.OpenAsTextStream(ForAppend, TristateFalse)
    'skriv netbrugernavn og tid til logfilen (tilføj)
    MyStream.WriteLine Environ("Username") & ", " & Now()
    'luk filen igen
    MyStream.Close
    'ryd op
    Set FSO = Nothing
    Set f = Nothing
    Set MyStream = Nothing
End Sub

Hej bak.
Jeg vil kaste mig over dit bud på en løsning ASAP.
Jeg er midt i "juleknaset".
Vender tilbage efter jul - glædelig jul

Super, virker perfekt efter hensigten, hvis du sender svar, skal jeg acceptere ASAP.

ok, jeg er stadig midt i "knaset" :-)

Godt nytår.