Angiv "Sidst opdateret" i et hovedark

aktiver din workbook og kør denne makro : GetLinksInfo
den danner et nyt ark, kaldet LastModified hvor den indsætter filnavnene på links'ene og sidst opdateret dato


Sub GetLinksInfo()
  Dim aLinks As Variant
  Dim i As Long
  Dim LM As Variant
  Dim sh As Worksheet
  On Error Resume Next
  Set sh = ActiveWorkbook.Worksheets("LastModified")
  If Err <> 0 Then
      Set sh = ActiveWorkbook.Worksheets.Add(Sheets(1))
      sh.Name = "LastModified"
  End If
  On Error GoTo 0
  aLinks = ActiveWorkbook.LinkSources(xlExcelLinks)
  If Not IsEmpty(aLinks) Then
      sh.Range("A1") = "Linked file"
      sh.Range("B1") = "Last modified"
      sh.Range("A1:B1").Font.Bold = True
      For i = 1 To UBound(aLinks)
        LM = GetLastModified(aLinks(i))
        sh.Range("A1")(i + 1, 1) = aLinks(i)
        sh.Range("B1")(i + 1, 1) = LM
      Next i
  End If
  sh.Columns("A:B").EntireColumn.AutoFit
End Sub


Function GetLastModified(filespec) As Variant
  Dim fs, f, s
  Set fs = CreateObject("Scripting.FileSystemObject")
  On Error GoTo ErrHandle
  Set f = fs.GetFile(filespec)
  GetLastModified = f.DateLastModified
  Exit Function
ErrHandle:
  GetLastModified = " File not found"
End Function