Ændring af en bestemt celle i flere ws, som ligger i samme bib.

Public Sub test()
    Dim strFilNavn(100) As Variant, Mypath As String, NR As Integer, I As Integer
    Mypath = "C:\Test\"    ' ret til din sti
    If Right(Mypath, 1) <> "\" Then Mypath = Mypath & "\"
    NR = 0
    strFilNavn(NR) = Dir(Mypath & "*.xls")  ' Hent den første filnavn.

    Do While strFilNavn(NR) <> ""  ' Start løkken
        If strFilNavn(NR) <> "." And strFilNavn(NR) <> ".." Then
            NR = NR + 1
        End If

        strFilNavn(NR) = Dir    ' Hent næste filnavn.
    Loop
    Application.ScreenUpdating = False
    For I = 0 To NR - 1
        Workbooks.Open (Mypath & strFilNavn(I))    ' åbner regneark
        ActiveWorkbook.Worksheets("Ark1").Range("A1") = 20    ' skriver i en celle
        ActiveWorkbook.Close savechanges:=True    ' lukker og gemmer
    Next
    Application.ScreenUpdating = False

End Sub

Hej Kabbak - det virker perfekt :o), så sidste del af opgaven er løst. Har du mod på første del?

ups - min kollega var lidt hurtiger end mig - vi arbejder sammen om projektet - men tak for hjælpen med sidste del.

Hvordan vil du vælge filen ??

hvis det er muligt vil jeg gerne kunne vælge den fra en dropdown box

Ok, lav en Userform med 3 Tekstbokse og en commandknap

Her er koden til knappen, ret selv til

Private Sub CommandButton1_Click()
Dim FileToOpen As Variant
Application.ScreenUpdating = False
FileToOpen = Application.GetOpenFilename("Excelfiler (*.xls), *.xls")
    If FileToOpen <> False Then
        Workbooks.Open (FileToOpen)    ' åbner regneark
        ActiveWorkbook.Worksheets("Ark1").Range("A1") = Me.TextBox1    ' skriver i en celle
        ActiveWorkbook.Worksheets("Ark1").Range("A2") = Me.TextBox2
        ActiveWorkbook.Worksheets("Ark1").Range("A3") = Me.TextBox3
        ActiveWorkbook.Close savechanges:=True    ' lukker og gemmer
    End If
    Application.ScreenUpdating = False
End Sub

et svar ;-))

hej Kabak - den virker ikke helt endnu. Jeg kan fint åbne udfylde og åbne et ark, men der skrives ikke noget i arket. Det smarte vil være om man først åbner arket, derefter udfylder felterne og dernæst gemmer.

Virker fint her, Har du husket at rette arknavn, celle og navnene på tekstboksene

det gør den også hos mig nu - lidt underligt, men det virker. Kan du afslutningsvis vise, hvordan jeg i koden kan forubestemme i hvilket katalog der åbnes som default?
mvh / hubertus

Det tror jeg ikke man kan, som standard er det vist, hvor excelmappen med koden i ligger.

det er ok - Tak for hjælpen det sparer mig for meget arbejde. :-)

Hej Kabak
Burde følgende ikke bevirke at jeg fik indlæst infomationer i userformen?

Private Sub cmdopen_Click()
Dim FileToOpen As Variant
FileToOpen = Application.GetOpenFilename("Excelfiler (*.xls), *.xls")
Me.txtårstal = ActiveWorkbook.Worksheets("Ark1").Range("a1")
Me.txtfag = ActiveWorkbook.Worksheets("Ark1").Range("c3")
Me.txtformand = ActiveWorkbook.Worksheets("Ark1").Range("A35")
End Sub

det var med henblik på at kunne ændre i felterne og dernæst gemme

Du glemte at åbne og lukke

Private Sub cmdopen_Click()
    Dim FileToOpen As Variant
    FileToOpen = Application.GetOpenFilename("Excelfiler (*.xls), *.xls")
    If FileToOpen <> False Then
        Workbooks.Open (FileToOpen)
        Me.txtårstal.Text = ActiveWorkbook.Worksheets("Ark1").Range("a1").Text
        Me.txtfag.Text = ActiveWorkbook.Worksheets("Ark1").Range("c3").Text
        Me.txtformand.Text = ActiveWorkbook.Worksheets("Ark1").Range("A35").Text
        ActiveWorkbook.Close savechanges:=True    ' lukker og gemmer
    End If
End Sub

Kabak - den havde jeg overset - er ikke vandt til at arbejde med åbne lukke filer.
Tak for hjælpen.

Hej kabak - sætter lig nogle flere point på højkant

Jeg har brug for at kunne ændre linien   
ActiveWorkbook.Close savechanges:=True   
således at jeg kan gemme under et andet filnavn. (svarende til gem som). Kan du hjælpe med det?

Denne øverst i makroen
    Dim fName As Variant


Erstat

ActiveWorkbook.Close savechanges:=True    ' lukker og gemmer

med nedenstående


    fName = Application.GetSaveAsFilename( _
            fileFilter:="Excelfiler  (*.xls), *.xls")
    If fName <> False Then
        ActiveWorkbook.SaveAs Filename:=fName
    Else
        MsgBox " Mappen er ikke gemt"
    End If

Hej Kabbak - det var lige det jeg søgte. Jeg opretter lige et spørgsmål, så du kan få nogle point.

behøves ikke, det er service ;-))

Tak for det - ha en god aften :-)

selv tak