Værktøjslinie ?

Når arket lukkes skal det kontrollere om det er den sidste (eneste) kopi der er åben, og kun lukke værktøjslinjen i dette tilfælle.

Kan du hjælpe med denne makro ?

Jeg vil også gerne have en forklaring på hvorfor man ikke kan højreklikke på toppen af Excel og vælge sin værktøjslinie på listen, ligesom med standardværktøjslinierne i Excel.

Hvis du altså ved hvorfor...

Det ideelle havde været at se om et at de andre arbejdsområder havde værktøjslinjen tilknyttet, men det kan man ikke.

Citat fra Excel Visual Basic Reference (2000):

CommandBars Property

...

There is no programmatic way to return the set of command bars attached to a workbook.

Man må falde tilbage på en løsning der involverer en liste af arbejdsområder der bruger værktøjslinjen, der så må være global.

Option Explicit
Private Function inList(ByVal actName As String)
    Dim customBooks, name, found
    customBooks = Array( _
        "Periodeantal.xls", _
        "Pointregnskab.xls")
    inList = False
    For Each name In customBooks
        If actName = name Then
            inList = True
            Exit For
        End If
    Next
End Function
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim app As Application, bks As Workbooks, bk As Workbook
    Dim idx, cnt As Integer
    Dim actName As String
    Dim inUse As Boolean
    Set app = ActiveWorkbook.Parent ' Find Excel.Application
    actName = ActiveWorkbook.name
    Set bks = app.Workbooks
    inUse = False
    cnt = bks.Count
    For idx = 1 To cnt
        Set bk = bks.Item(idx)
        If bk.name <> actName Then
            If inList(bk.name) Then inUse = True
        End If
    Next idx
    If Not inUse Then Application.CommandBars("Lokale værktøjer").Visible = False
End Sub
Private Sub Workbook_Open()
    Application.CommandBars("Lokale værktøjer").Visible = True
End Sub

Jeg er nok nødt til at få forklaret lidt mere uddybende hvordan jeg inddrager denne makro i mit regneark.

Makro'en skal indsættes i alle de arbejdområder der bruger værktøjslinjen "Lokale værktøjer".
Array'et "customBooks" skal indeholde alle navnene på disse arbejdområder.

1. Tast Alt-F11 for at åbne Visualbasic fra Excel
2. Dobbeltklik på arbejsområdet.
3. Indsæt makro'en i ThisWorkbook (code)

Værktøjslinjen vil blive vist så længe bare ét af de opremsede arbejdsområder er åbne.

For at sikre visning når man vender tilbage til et af dem kan denne bruges:

Private Sub Workbook_Activate()
    Application.CommandBars("Lokale værktøjer").Visible = True
End Sub

En løsning kunne være at have disse to med i alle arbejdsområder:


Private Sub Workbook_Activate()
    Application.CommandBars("Lokale værktøjer").Visible = True
End Sub

Private Sub Workbook_Deactivate()
    Application.CommandBars("Lokale værktøjer").Visible = False
End Sub


Kan du bruge noget af det?

Hej Mira96ac.
Har du fundet en løsning?
Lad mig vide hvordan det går :o)
Hilsen jhe-ting

Har lige fået tid til at kigge på det.

Det virker.

Tak for hjælpen.