tilføj nyt fortløbendenr.

you stil have an open question http://www.eksperten.dk/spm/758007
I gave a link there which allows you to download an example database with queries. One of these examples explains how you give a number to each line in a query.

If you printout is one report then I doubt that its possible to see how far you have come. Once the report is sent to the printer then its out of Access's hands.

.

Terry > ved jeg, har ikke lige haft tid til at kigge på det andet spørgsmål - det har lige været noget mere pressende på arbejdet. Faktiske denne opgave.
Men jeg skal nok kigge på det andet i morgen eller fredag.

Jeg printer ud via Printshop Mail, og det er små 100.000 så det vil være rart at se hvor langt jeg er kommet.

Donmt know anything about Printshop mail.
"små 100.00"? records?
If they come out in the same reprot then I dont think you can.

Kender det ikke så godt i nu, fik det i mandags, men virker til at være et godt program.
Jeg tror jeg eksportere db og skriver så det fortløbendenr. ved eksport.

Her er et eksempel, som starter en autonummerering fra 7500 i tabel tblClient!~)

Call SetAutoNumber("tblClient", 7500)
--------------------------------------------------------------------------------

Sub SetAutoNumber(sTable As String, ByVal lNum As Long)
On Error GoTo Err_SetAutoNumber
    ' Purpose:      set the AutoNumber field in sTable to begin at lNum.
    ' Arguments:    sTable = name of table to modify.
    '              lNum = the number you wish to begin from.
    ' Sample use:  Call SetAutoNumber("tblInvoice", 1000)
    Dim db As DAO.Database      ' Current db.
    Dim tdf As DAO.TableDef    ' TableDef of sTable.
    Dim i As Integer            ' Loop counter
    Dim fld As DAO.Field        ' Field of sTable.
    Dim sFieldName As String    ' Name of the AutoNumber field.
    Dim vMaxID As Variant      ' Current Maximum AutoNumber value.
    Dim sSQL As String          ' Append/Delete query string.
    Dim sMsg As String          ' MsgBox string.

    lNum = lNum - 1            ' Assign to 1 less than desired value.

    ' Locate the auto-incrementing field for this table.
    Set db = CurrentDb()
    Set tdf = db.TableDefs(sTable)
    For i = 0 To tdf.Fields.Count - 1
        Set fld = tdf.Fields(i)
        If fld.Attributes And dbAutoIncrField Then
            sFieldName = fld.name
            Exit For
        End If
    Next

    If Len(sFieldName) = 0 Then
        sMsg = "No AutoNumber field found in table """ & sTable & """."
        MsgBox sMsg, vbInformation, "Cannot set AutoNumber"
    Else
        vMaxID = DMax(sFieldName, sTable)
        If IsNull(vMaxID) Then vMaxID = 0
        If vMaxID >= lNum Then
            sMsg = "Supply a larger number. """ & sTable & "." & _
                sFieldName & """ already contains the value " & vMaxID
            MsgBox sMsg, vbInformation, "Too low."
        Else
            ' Insert and delete the record.
            sSQL = "INSERT INTO " & sTable & " ([" & sFieldName & "]) SELECT " & lNum & " AS lNum;"
            db.Execute sSQL, dbFailOnError
            sSQL = "DELETE FROM " & sTable & " WHERE " & sFieldName & " = " & lNum & ";"
            db.Execute sSQL, dbFailOnError
        End If
    End If
Exit_SetAutoNumber:
    Exit Sub

Err_SetAutoNumber:
    MsgBox "Error " & Err.Number & ": " & Err.Description, , "SetAutoNumber()"
    Resume Exit_SetAutoNumber
End Sub