Er IP indenfor range?

Hvis du kan lave "80.140.0.0" om til "080.140.000.000", så kan du sammenligne direkter med <= og >=

Du kan måske låne lidt fra IP2Location's script til at gøre det du vil:
// Function to convert IP address (xxx.xxx.xxx.xxx) to IP number (0 to 256^4-1)
function Dot2LongIP ($IPaddr) {
if ($IPaddr == "")
{
  return 0;
} else {
  $ips = split ("\.", "$IPaddr");
  return ($ips[3] + $ips[2] * 256 + $ips[1] * 256 * 256 + $ips[0] * 256 * 256 * 256);
}
}

Kode på:
http://www.ip2location.com/articles/article2.htm

hov :)
Havde bare klikket på spørgsmålet fra forsiden, troede det var php.
Så kan du nok ikke bruge det :)

ellers kan den vel klares med en split funktion hvor du splitter ved punktummer? Det ser faktisk ud til at det er det samme som den der php løsning gør (selvom jeg ikke er php kyndig)

okay det ved jeg så ikke, jeg er vist ikke god nok til ASP til at kunne få noget til at fungere ud fra dette.

Meget simpelt eksempel i VBScript

<%

    ip1 = "080140000000"
    ip2 = "080140255255"
   
   
    function inside(ip)
      a = split(ip,".")
      for i=lbound(a) to ubound(a)
        do while len(a(i))<3
          a(i) = "0" & a(i)
        loop
      next
      ip= a(0) & a(1) & a(2) & a(3)
      if ip>=ip1 and ip<=ip2 then
        inside=true
      else
        inside=false
      end if
    end function
   
    response.write inside("80.140.10.4") & "<br>"
    response.write inside("81.140.10.4") & "<br>"
   
%>

ipnr = "80.140.0.0"

ipok = split(ipnr,".")

if ipok(0) ="80" and ipok(1)="140" then response.write "ok"

Det ser rigtigt godt ud erikjacobsen, men jeg har lidt problemer.

jeg har omdøbt lidt på variabelnavnene for at jeg havde lidt lettere ved at se mig ud af det, det jeg kom frem til er:

Function CheckIP(strIP, startIP, slutIP)
    arrIP = split(strIP,".")
      for i=lbound(arrIP) to ubound(arrIP)
        do while len(arrIP(i))<3
          arrIP(i) = "0" & arrIP(i)
        loop
      next
      strIP= arrIP(0) & arrIP(1) & arrIP(2) & arrIP(3)
      if strIP>=startIP and strIP<=slutIP then
        CheckIP=true
      else
        CheckIP=false
      end if
End Function


Jeg har så lave en lille testside, men den melder "false" hvor den ikke skulle:

<!--#include file="funktioner.inc.asp"-->
<%
IP =        "87.72.13.143"
StartIP =    "87.72.0.0"
SlutIP =    "87.72.255.255"
%>
<table border=1 cellpadding=5 cellspacing=0>
  <tr><td>Testet IP:</td><td><b><%=IP%></b></td></tr>
  <tr><td>Start IP:</td><td><b><%=StartIP%></b></td></tr>
  <tr><td>Slut IP:</td><td><b><%=SlutIP%></b></td></tr>
  <tr><td>Test Resultat:</td><td><b><%=CheckIP(IP,StartIP,SlutIP)%></b></td></tr>
</table>

Den giver mig resultatet:
Testet IP:      87.72.13.143
Start IP:     87.72.0.0
Slut IP:     87.72.255.255
Test Resultat:     False

Jeg kan dog ikke se hvorfor, for som jeg tyder din kode burde det være korrekt?

argh nevermind, jeg tror jeg har fundet min fejl - jeg fjerner jo ikke punktummer eller noget fra mine test-ip'er....

Okay her er hvad jeg endte med som virker:

Function ConvertIP(strIP)
    arrIP = split(strIP,".")
      for i=lbound(arrIP) to ubound(arrIP)
        do while len(arrIP(i))<3
          arrIP(i) = "0" & arrIP(i)
        loop
      next
      ConvertIP= arrIP(0) & arrIP(1) & arrIP(2) & arrIP(3)
End Function

Function CheckIP(strIP, startIP, slutIP)
      if ConvertIP(strIP)>=ConvertIP(startIP) and ConvertIP(strIP)<=ConvertIP(slutIP) then
        CheckIP=true
      else
        CheckIP=false
      end if
End Function

<!--#include file="funktioner.inc.asp"-->
<%
IP =        "87.72.13.143"
StartIP =    "87.72.0.0"
SlutIP =    "87.72.255.255"
%>
<table border=1 cellpadding=5 cellspacing=0>
  <tr><td>Testet IP:</td><td><b><%=IP%></b></td></tr>
  <tr><td>Start IP:</td><td><b><%=StartIP%></b></td></tr>
  <tr><td>Slut IP:</td><td><b><%=SlutIP%></b></td></tr>
  <tr><td>Test Resultat:</td><td><b><%=CheckIP(IP,StartIP,SlutIP)%></b></td></tr>
</table>

Den giver mig resultatet:
Testet IP:      87.72.13.143
Start IP:    87.72.0.0
Slut IP:    87.72.255.255
Test Resultat:    True

forresten erikjacobsen - du må lægge et svar for points.

Jeg samler slet ikke på point, tak.

okay fair nok :-)
Tak for hjælpen ihverfald!